rendezvous with cassidoo challenge: 23.02.26

repeated_groups.clj

(ns repeated-groups
  (:require [clojure.test :refer [deftest is]))
  
(defn repeated-groups [nums]
  (->> nums
       (partition-by identity)
       (filter #(> (count %) 1))
       (into [])))
       
;; Using transducers instead which gives 
;; a huge speedup for larger vecs (shown
;; below):
(defn repeated-groups-transducer [nums]
  (let [xform (comp
                (partition-by identity)
                (filter #(> (count %) 1)))]
    (into [] xform nums)))

;; (def nums (into [] (repeatedly 1000000 #(rand-int 10))))
;; (require '[criterium.core :as cc])
;; (cc/quick-bench (repeated-groups nums))           ;; around 271ms
;; (cc-quick-bench (repeated-groups-transduce nums)) ;; around 61ms
;; (= (repeated-groups nums) (repeated-groups-transduce nums)) ;; true

(deftest repeated-groups-test
  (is (= (repeated-groups [1 2 2 4 5]) [[2 2]]))
  (is (= (repeated-groups [1 1 0 0 8 4 4 4 3 2 1 9 9]) [[1 1] [0 0] [4 4 4] [9 9]])))