rivetOffsetUV.mel

// Copyright (C) 2000-2001 Michael Bazhutkin - Copyright (C) 2000 studio Klassika
// www.geocites.com/bazhutkin
// [email protected]
//
//  Rivet (button) 1.0
//  Script File
//  MODIFY THIS AT YOUR OWN RISK
//
//  Creation Date:  April 13, 2001
//
//
//  Description:
//	Use "Rivet" to constrain locator to polygon or NURBS surfaces
//	Select two edges on polygon object
//	or select one point on NURBS surface and call rivet
//	Parent your rivets and buttons to this locator
//
//	Modfied by Hyuk Ko ([email protected]) - Added Offset UV attributes to channelbox.(Two edges method only)
//
//  Usage:
//	source rivetOffsetUV

global proc string rivet ( )
{

string $nameObject;
string $namePOSI;

string $parts[];
string $list[] = `filterExpand -sm 32`;
int $size = size($list);
if ($size > 0)
{
	if ($size != 2)
	{	error("No two edges selected");
		return "";
	}

	tokenize($list[0],".",$parts);
	$nameObject = $parts[0];
	tokenize($list[0],"[]",$parts);
	float $e1 = $parts[1];
	tokenize($list[1],"[]",$parts);
	float $e2 = $parts[1];

	string $nameCFME1 = `createNode curveFromMeshEdge -n "rivetCurveFromMeshEdge1"`;
		setAttr ".ihi" 1;
		setAttr ".ei[0]"  $e1;
	string $nameCFME2 = `createNode curveFromMeshEdge -n "rivetCurveFromMeshEdge2"`;
		setAttr ".ihi" 1;
		setAttr ".ei[0]"  $e2;
	string $nameLoft = `createNode loft -n "rivetLoft1"`;
		setAttr -s 2 ".ic";
		setAttr ".u" yes;
		setAttr ".rsn" yes;

	$namePOSI = `createNode pointOnSurfaceInfo -n "rivetPointOnSurfaceInfo1"`;
		setAttr ".turnOnPercentage" 1;
		setAttr ".parameterU" 0.5;
		setAttr ".parameterV" 0.5;

	connectAttr -f ($nameLoft + ".os") ($namePOSI + ".is");
	connectAttr ($nameCFME1 + ".oc") ($nameLoft + ".ic[0]");
	connectAttr ($nameCFME2 + ".oc") ($nameLoft + ".ic[1]");
	connectAttr ($nameObject + ".w") ($nameCFME1 + ".im");
	connectAttr ($nameObject + ".w") ($nameCFME2 + ".im");

	string $nameLocator = `createNode transform -n "rivet1"`;
		addAttr -shortName offsetU -longName Offset_U -defaultValue 0.5 -minValue 0.0 -maxValue 1.0; //hko
		addAttr -shortName offsetV -longName Offset_V -defaultValue 0.5 -minValue 0.0 -maxValue 1.0; //hko
		setAttr -k on ".offsetU"; //hko
		setAttr -k on ".offsetV"; //hko
	createNode locator -n ($nameLocator + "Shape") -p $nameLocator;

		connectAttr -f ($nameLocator + ".offsetU") ($namePOSI + ".parameterU"); //hko
		connectAttr -f ($nameLocator + ".offsetV") ($namePOSI + ".parameterV"); //hko

	string $nameAC = `createNode aimConstraint -p $nameLocator -n ($nameLocator + "_rivetAimConstraint1")`;
		setAttr ".tg[0].tw" 1;
		setAttr ".a" -type "double3" 0 1 0;
		setAttr ".u" -type "double3" 0 0 1;
		setAttr -k off ".v";
		setAttr -k off ".tx";
		setAttr -k off ".ty";
		setAttr -k off ".tz";
		setAttr -k off ".rx";
		setAttr -k off ".ry";
		setAttr -k off ".rz";
		setAttr -k off ".sx";
		setAttr -k off ".sy";
		setAttr -k off ".sz";

	connectAttr ($namePOSI + ".position") ($nameLocator + ".translate");
	connectAttr ($namePOSI + ".n") ($nameAC + ".tg[0].tt");
	connectAttr ($namePOSI + ".tv") ($nameAC + ".wu");
	connectAttr ($nameAC + ".crx") ($nameLocator + ".rx");
	connectAttr ($nameAC + ".cry") ($nameLocator + ".ry");
	connectAttr ($nameAC + ".crz") ($nameLocator + ".rz");

	select -r $nameLocator;
	return ($nameLocator);
	
}
else
{	$list = `filterExpand -sm 41`;
	$size = size($list);

	if ($size > 0)
	{
		if ($size != 1)
		{	error("No one point selected");
			return "";
		}
		tokenize($list[0],".",$parts);
		$nameObject = $parts[0];
		tokenize($list[0],"[]",$parts);
		float $u = $parts[1];
		float $v = $parts[2];
		$namePOSI = `createNode pointOnSurfaceInfo -n "rivetPointOnSurfaceInfo1"`;
				setAttr ".turnOnPercentage" 0;
				setAttr ".parameterU" $u;
				setAttr ".parameterV" $v;
		connectAttr -f ($nameObject + ".ws") ($namePOSI + ".is");

		string $nameLocator = `createNode transform -n "rivet1"`;

		createNode locator -n ($nameLocator + "Shape") -p $nameLocator;

		string $nameAC = `createNode aimConstraint -p $nameLocator -n ($nameLocator + "_rivetAimConstraint1")`;
			setAttr ".tg[0].tw" 1;
			setAttr ".a" -type "double3" 0 1 0;
			setAttr ".u" -type "double3" 0 0 1;
			setAttr -k off ".v";
			setAttr -k off ".tx";
			setAttr -k off ".ty";
			setAttr -k off ".tz";
			setAttr -k off ".rx";
			setAttr -k off ".ry";
			setAttr -k off ".rz";
			setAttr -k off ".sx";
			setAttr -k off ".sy";
			setAttr -k off ".sz";

		connectAttr ($namePOSI + ".position") ($nameLocator + ".translate");
		connectAttr ($namePOSI + ".n") ($nameAC + ".tg[0].tt");
		connectAttr ($namePOSI + ".tv") ($nameAC + ".wu");
		connectAttr ($nameAC + ".crx") ($nameLocator + ".rx");
		connectAttr ($nameAC + ".cry") ($nameLocator + ".ry");
		connectAttr ($nameAC + ".crz") ($nameLocator + ".rz");

		select -r $nameLocator;
		return ($nameLocator);

	}
	else
	{	error("No edges or point selected");
		return "";
	}
}

}

rivet;