Заменить на поправленные.cmd

@echo off
chcp 1251
cls
cd /d "%~dp0"
set "d=%windir%\Fonts"
set "f1=msgothic.ttc"
set "f2=msmincho.ttc"
set s1=0
set s2=0
set "t1=Проверяем "
set "t2=: изменённый и будет пропущен!"
set "t3=: OK."
set "t4=Нажмите любую клавишу для выхода."
<nul set /p sTemp=%t1% %f1%
pushd "%d%" & call:size1 "%f1%"
exit
:size1
if %~z1 equ 33684264 (
	set s1=1
	<nul set /p sTemp=%t2%
) else ( <nul set /p sTemp=%t3% )
echo.
<nul set /p sTemp=%t1% %f2%
pushd "%d%" & call:size2 "%f2%"
exit
:size2
if %~z1 equ 25159716 (
	set s2=1
	<nul set /p sTemp=%t2%
) else ( <nul set /p sTemp=%t3% )
echo.
if %s1% equ 1 (
	if %s2% equ 1 ( 
		echo Шрифты уже изменены! 
		echo %t4%
		pause>nul
		exit
	)
)

reg query "HKU\S-1-5-19">nul 2>&1 && set isAdmin=1
IF NOT DEFINED isAdmin (
	echo Требуются права уровня администратора!
	echo %t4%
	pause>nul
	exit
)

echo Создаём папку запаски
md "%~dp0\backup\"
echo Делаем запаску системных шрифтов
if %s1% equ 0 ( copy %windir%\Fonts\%f1% "%~dp0\backup\" )
if %s2% equ 0 ( copy %windir%\Fonts\%f2% "%~dp0\backup\" )
echo Делаем запаску прав доступа на шрифты
icacls %windir%\Fonts\* /save "%~dp0\backup\fonts.acl" /T /Q
echo Назначаем полные права доступа группе администраторов
if %s1% equ 0 ( icacls %windir%\Fonts\%f1% /grant *S-1-5-32-544:F )
if %s2% equ 0 ( icacls %windir%\Fonts\%f2% /grant *S-1-5-32-544:F )
:: *S-1-5-32-544 -- группа администраторов.
echo Удаляем системные шрифты
if %s1% equ 0 ( del %windir%\Fonts\%f1% )
if %s2% equ 0 ( del %windir%\Fonts\%f2% )
echo Копируем изменённые шрифты
if %s1% equ 0 ( copy "%~dp0\fixed\%f1%" %windir%\Fonts\ )
if %s2% equ 0 ( copy "%~dp0\fixed\%f2%" %windir%\Fonts\ )
echo Восстанавливаем права доступа
icacls %windir%\Fonts\ /restore "%~dp0\backup\fonts.acl" /Q

echo Чтобы изменения вступили в силу надо перелогиниться или перезагрузиться.
choice /M "Разлогиниться?"
IF ERRORLEVEL=2 ( exit )
IF ERRORLEVEL=1 ( Shutdown.exe -l )

Откатить на системные.cmd

@echo off
chcp 1251
cls
cd /d "%~dp0"
set "d=%windir%\Fonts"
set "f1=msgothic.ttc"
set "f2=msmincho.ttc"
set s1=0
set s2=0
set "t1=Проверяем "
set "t2=: системный и будет пропущен!"
set "t3=: OK."
set "t4=Нажмите любую клавишу для выхода."
<nul set /p sTemp=%t1% %f1%
pushd "%d%" & call:size1 "%f1%"
exit
:size1
if %~z1 equ 33684264 (
	set s1=1
	<nul set /p sTemp=%t3%
) else ( <nul set /p sTemp=%t2% )
echo.
<nul set /p sTemp=%t1% %f2%
pushd "%d%" & call:size2 "%f2%"
exit
:size2
if %~z1 equ 25159716 (
	set s2=1
	<nul set /p sTemp=%t3%
) else ( <nul set /p sTemp=%t2% )
echo.
if %s1% equ 0 (
	if %s2% equ 0 ( 
		echo Шрифты уже возвращены! 
		echo %t4%
		pause>nul
		exit
	)
)

reg query "HKU\S-1-5-19">nul 2>&1 && set isAdmin=1
IF NOT DEFINED isAdmin (
	echo Требуются права уровня администратора!
	echo %t4%
	pause>nul
	exit
)

echo Назначаем полные права доступа группе администраторов
if %s1% equ 1 ( icacls %windir%\Fonts\%f1% /grant *S-1-5-32-544:F )
if %s2% equ 1 ( icacls %windir%\Fonts\%f2% /grant *S-1-5-32-544:F )
echo Удаляем изменённые шрифты
if %s1% equ 1 ( del %windir%\Fonts\%f1% )
if %s2% equ 1 ( del %windir%\Fonts\%f2% )
echo Копируем системные шрифты
if %s1% equ 1 ( copy "%~dp0\backup\%f1%" %windir%\Fonts\ )
if %s2% equ 1 ( copy "%~dp0\backup\%f2%" %windir%\Fonts\ )
echo Восстанавливаем права доступа
icacls %windir%\Fonts\ /restore "%~dp0\backup\fonts.acl" /Q

echo Чтобы изменения вступили в силу надо перелогиниться или перезагрузиться.
choice /M "Разлогиниться?"
IF ERRORLEVEL=2 ( exit )
IF ERRORLEVEL=1 ( Shutdown.exe -l )