Something Penguin Something (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

(-
 - Version 0.1.3b
)

title Something Penguin Something
author 10c8
homepage 10c8.github.io

background_color #002E8E

realtime_interval 0.1

run_rules_on_level_start
(verbose_logging)

========
OBJECTS
========
BACKGROUND
#002E8E

SNOW_COVER
#FCFCFC
.....
.....
.....
.....
00000
SNOW_COVER_DOWN
#FCFCFC
.....
.....
.....
.....
00000
SNOW
#FCFCFC
SNOW_BELOW_ICE
#00B9FF
00000
00000
.....
.....
.....
SNOW_BELOW_WATER
#1564C5 #C3CBDB
11111
00000
00000
.....
.....
SNOW_BELOW_WATER_DL
#1564C5 #C3CBDB
01111
00000
.0000
.....
.....
SNOW_BELOW_WATER_DR
#1564C5 #C3CBDB
11110
00000
0000.
.....
.....
SNOW_SMALL
#FCFCFC #BCC5D7
.....
.....
.....
00000
11111
SNOW_COVER_UL
#FCFCFC
.....
.....
.....
.....
.0000
SNOW_COVER_UR
#FCFCFC
.....
.....
.....
.....
0000.
SNOW_CORNER_UL Ø
#FCFCFC
SNOW_CORNER_UR Ô
#FCFCFC
SNOW_CORNER_DL ˚
#FCFCFC #C3CBDB
00000
00000
00000
00000
10000
SNOW_CORNER_DR ¬
#FCFCFC #C3CBDB
00000
00000
00000
00000
00001
SNOW_BORDER Á
#C3CBDB
.....
.....
.....
.....
00000

STEP_U
TRANSPARENT #C3CBDB
00000
00010
01010
01000
00000
STEP_D
TRANSPARENT #C3CBDB
00000
01000
01010
00010
00000
STEP_L
TRANSPARENT #C3CBDB
00000
01100
00000
00110
00000
STEP_R
TRANSPARENT #C3CBDB
00000
00110
00000
01100
00000

STONE_COVER
#888C78
.....
.....
.....
.000.
00000
STONE
#888C78 #585551 #FCFCFC #BCC5D7
00000
10001
11111
21112
33333

ICE
#A096D1
ICE_LEFT Í
#FCFCFC #C3CBDB #A096D1
12222
22222
22222
02222
00000
ICE_LEFT_COVER Î
#FCFCFC #C3CBDB
00000
00000
00000
00000
01111

HOLE_DOUBLE
#002E8E
HOLE_SNOW ˛
#C3CBDB #002E8E
00000
00000
11111
11111
11111
HOLE_ICE Ç
#1564C5 #002E8E
00000
00000
11111
11111
11111
HOLE_FILLED
#7A3A02 #AF6B01
00100
00100
00100
00100
00100

PLAYER_TOP_D
#000000 #888C78 #FFD800 
.....
.000.
00000
01010
00200
PLAYER_D
#000000 #FCFCFC #FFD800 #585551 #FF9000
03130
01110
01110
.4.4.
.....

PLAYER_TOP_U
#000000
.....
.000.
00000
00000
00000
PLAYER_U
#000000 #FF9000
00000
00000
00000
.1.1.
.....

PLAYER_TOP_L
#000000 #888C78 #FFD800
.....
..00.
.0000
.1000
20000
PLAYER_L
#000000 #FCFCFC #585551 #FF9000
.1220
.1220
.0200
..33.
.....

PLAYER_TOP_R
#000000 #888C78 #FFD800
.....
.00..
0000.
0001.
00002
PLAYER_R
#000000 #FCFCFC #585551 #FF9000
0221.
0221.
0020.
.33..
.....

Stop
TRANSPARENT

Floor
GRAY

FloorWet
#008DF0
FloorWetDeco
#00B9FF
.....
.0...
..0..
...0.
.....
FloorWetDecoNone0
TRANSPARENT
FloorWetDecoNone1
TRANSPARENT
FloorWetDecoNone2
TRANSPARENT

EXIT
TRANSPARENT

CRATE_TOP
#B77803 #D6A60B
00100
00100
00100
00100
00100
CRATE
#2C001B #864906 #6C2903 #D6A60B
11111
11131
11111
13331
11111

ButtonBlue
#BE09E7 #520674
00000
01110
01110
01110
00000
ButtonYellow
#FFFC1E #FF8400
00000
01110
01110
01110
00000
ButtonGreen
#9DEB00 #3BB103
00000
01110
01110
01110
00000
ButtonRed
#E93100 #BF0000
00000
01110
01110
01110
00000

GateBlue
#520674
.000.
.000.
.000.
..0..
.....
GateYellow
#FF8400
.000.
.000.
.000.
..0..
.....
GateGreen
#4AB909
.000.
.000.
.000.
..0..
.....
GateRed
#BF0000
.000.
.000.
.000.
..0..
.....

GateBlueDown
#BE09E7
.....
..0..
.000.
..0..
.....
GateYellowDown
#FFFC1E
.....
..0..
.000.
..0..
.....
GateGreenDown
#A7ED00
.....
..0..
.000.
..0..
.....
GateRedDown
#E93100
.....
..0..
.000.
..0..
.....

GateBlueTop
#BE09E7 #520674
.....
.....
..0..
.000.
.101.
GateGreenTop
#A7ED00 #4AB909
.....
.....
..0..
.000.
.101.
GateYellowTop
#FFFC1E #FF8400
.....
.....
..0..
.000.
.101.
GateRedTop
#E93100 #BF0000
.....
.....
..0..
.000.
.101.

( Counter )
N0 0
WHITE
.000.
.0.0.
.0.0.
.0.0.
.000.

N1 1
WHITE
..0..
.00..
..0..
..0..
.000.

N2 2
WHITE
.000.
...0.
.000.
.0...
.000.

N3 3
WHITE
.000.
...0.
.000.
...0.
.000.

N4 4
WHITE
.0.0.
.0.0.
.000.
...0.
...0.

N5 5
WHITE
.000.
.0...
.000.
...0.
.000.

N6 6
WHITE
.000.
.0...
.000.
.0.0.
.000.

N7 7
WHITE
.000.
...0.
...0.
...0.
...0.

N8 8
WHITE
.000.
.0.0.
.000.
.0.0.
.000.

N9 9
WHITE
.000.
.0.0.
.000.
...0.
...0.

DIVIDER :
WHITE
.....
..0..
.....
..0..
.....

STOPPED
#BF0000

COUNTER
TRANSPARENT

( Tokens )
R_TICK '
TRANSPARENT
M_TICK "
TRANSPARENT

X
TRANSPARENT
Y
TRANSPARENT
Z
TRANSPARENT

INVERTER
TRANSPARENT

TIMER_0
TRANSPARENT
TIMER_1
TRANSPARENT
TIMER_2
TRANSPARENT
TIMER_3
TRANSPARENT

U
TRANSPARENT
D
TRANSPARENT
L
TRANSPARENT
R
TRANSPARENT

ACTIVE
TRANSPARENT
PREPARING
TRANSPARENT
DONE
TRANSPARENT

=======
LEGEND
=======
PLAYER_TOPS = PLAYER_TOP_U or PLAYER_TOP_D or PLAYER_TOP_L or PLAYER_TOP_R
PLAYER = PLAYER_U or PLAYER_D or PLAYER_L or PLAYER_R

( Tiles )
. = BACKGROUND
# = STONE
_ = SNOW
≥ = SNOW_SMALL
g = ICE
? = STOP
f = FLOOR
w = FloorWet
¶ = BACKGROUND AND INVERTER
© = SNOW AND INVERTER
∞ = ICE AND INVERTER
™ = FLOOR AND INVERTER
£ = FloorWet AND INVERTER
E = EXIT AND ICE
@ = PLAYER
! = PLAYER_D AND Snow

¿ = SNOW_COVER AND STOP
Ú = SNOW_COVER_UL AND STOP
Æ = SNOW_COVER_UR AND STOP

« = SNOW_BELOW_WATER_DL AND STOP
» = SNOW_BELOW_WATER AND STOP
∏ = SNOW_BELOW_WATER_DR AND STOP

C = CRATE AND Floor
N = CRATE AND FloorWet

% = CRATE AND ButtonBlue
& = CRATE AND ButtonYellow
* = CRATE AND ButtonGreen
{ = CRATE AND ButtonRed

œ = ButtonBlue
∑ = ButtonYellow
´ = ButtonGreen
® = ButtonRed

† = GateBlue AND FLOOR
¥ = GateYellow AND FLOOR
¨ = GateGreen AND FLOOR
ˆ = GateRed AND FLOOR

… = GateBlue AND FloorWet
; = GateYellow AND FloorWet
} = GateGreen AND FloorWet
\ = GateRed AND FloorWet

+ = GateBlue AND ICE
¡ = GateYellow AND ICE
~ = GateGreen AND ICE
` = GateRed AND ICE

( Tile groups )
GROUND = _ or f or FloorWet or SNOW_CORNER_UL or SNOW_CORNER_UR or SNOW_CORNER_DL or SNOW_CORNER_DR
GATE = GateBlue or GateYellow or GateGreen or GateRed
GATE_TOP = GateBlueTop or GateYellowTop or GateGreenTop or GateRedTop
GATEDOWN = GateBlueDown or GateYellowDown or GateGreenDown or GateRedDown
BUTTON = ButtonBlue or ButtonYellow or ButtonGreen or ButtonRed
OBSTACLE = SNOW or GATE or STOP or CRATE or STONE
COVERED = SNOW or STONE or ICE
HOLES = HOLE_SNOW or HOLE_ICE or HOLE_DOUBLE
SNOW_COVERS = SNOW_COVER or SNOW_COVER_DOWN
SNOWS = SNOW or SNOW_CORNER_DL or SNOW_CORNER_DR or SNOW_BELOW_WATER or SNOW_BELOW_WATER_DL or SNOW_BELOW_WATER_DR or ICE_LEFT_COVER
COVERS_SNOW_ICE = W
COVERS_SNOW_WATER = STOP
THING = f or FloorWet
STEP = STEP_U or STEP_D or STEP_L or STEP_R
FLOOR_DECO = FloorWetDeco or FloorWetDecoNone0 or FloorWetDecoNone1 or  FloorWetDecoNone2
STOPPER = STOP or SNOW_SMALL
GETS_STEPPED = SNOW or SNOW_CORNER_UL or SNOW_CORNER_UR or SNOW_CORNER_DL or SNOW_CORNER_DR

( Tokens )
DIR = U OR D OR L OR R

( Counter )
µ = COUNTER
NUM = N0 or N1 or N2 or N3 or N4 or N5 or N6 or N7 or N8 or N9
TIMER_T = X or Y or Z or U or D or L or R or TIMER_0 or TIMER_1 or TIMER_2 or TIMER_3

=======
SOUNDS
=======
sfx0 68242702  ( Failed to push )
sfx1 36772507  ( Push crate )
sfx2 69543507  ( Sliding crate )
sfx3 67045504  ( Hit obstacle )
sfx4 31851908  ( Fell into hole )
sfx5 30091907  ( Pressed button )
sfx6 32907709  ( Level cleared )

================
COLLISIONLAYERS
================
( Tiles )
BACKGROUND
STOP
SNOW_COVER_DOWN
GROUND ICE ICE_LEFT SNOW_SMALL
STEP_U STEP_D STEP_L STEP_R SNOW_BELOW_ICE
SNOW_COVER_UL SNOW_COVER_UR
EXIT ICE_LEFT_COVER FLOOR_DECO SNOW_BORDER
BUTTON GATEDOWN HOLE_FILLED
CRATE
PLAYER GATE STONE HOLES
STONE_COVER
PLAYER_TOPS
CRATE_TOP
GATE_TOP SNOW_BELOW_WATER SNOW_BELOW_WATER_DL SNOW_BELOW_WATER_DR
SNOW_COVER

( Tokens )
R_TICK M_TICK X Y INVERTER
Z
U D L R
PREPARING ACTIVE DONE

( Counter )
STOPPED
NUM DIVIDER COUNTER
TIMER_0 TIMER_1 TIMER_2 TIMER_3

======
RULES
======
( Realtime fix )
[ STATIONARY @ ] ["] -> [        @ ] [']
[ MOVING     @ ] ['] -> [ MOVING @ ] ["]

( Player movement )
UP    [ > @ ] -> [ > PLAYER_U ]
DOWN  [ > @ ] -> [ > PLAYER_D ]
LEFT  [ > @ ] -> [ > PLAYER_L ]
RIGHT [ > @ ] -> [ > PLAYER_R ]

[ > @ | STOPPER ] [ PLAYER_TOPS ] -> [ @ | STOPPER ] [ PLAYER_TOPS ]

(-
 - Decorations
)
( Footsteps )
['][ STEP R ] -> ['][ ]
['][ STEP L ] -> ['][ STEP R ]
['][ STEP D ] -> ['][ STEP L ]
['][ STEP U ] -> ['][ STEP D ] 
['][ STEP X ] -> ['][ STEP U ]
['][ STEP Y ] -> ['][ STEP X ]
['][ STEP Z ] -> ['][ STEP Y ]

UP    [ > @ | GETS_STEPPED ] -> [ > @ | GETS_STEPPED STEP_U Z ]
DOWN  [ > @ | GETS_STEPPED ] -> [ > @ | GETS_STEPPED STEP_D Z ]
LEFT  [ > @ | GETS_STEPPED ] -> [ > @ | GETS_STEPPED STEP_L Z ]
RIGHT [ > @ | GETS_STEPPED ] -> [ > @ | GETS_STEPPED STEP_R Z ]

( Ice cracks )
[ FloorWet NO FLOOR_DECO ] -> [ FloorWet RANDOM FLOOR_DECO ]

( Player sprite )
LATE UP [ PLAYER_U | ] -> [ PLAYER_U | PLAYER_TOP_U ]
LATE UP [ PLAYER_D | ] -> [ PLAYER_D | PLAYER_TOP_D ]
LATE UP [ PLAYER_L | ] -> [ PLAYER_L | PLAYER_TOP_L ]
LATE UP [ PLAYER_R | ] -> [ PLAYER_R | PLAYER_TOP_R ]

LATE DOWN [ PLAYER_TOPS | NO PLAYER ] -> [ | ]

( Floor decorations )
DOWN [ COVERED | COVERS_SNOW_ICE NO SNOW_BELOW_ICE ] -> [ COVERED | COVERS_SNOW_ICE SNOW_BELOW_ICE ]

DOWN [ ICE NO SNOW_COVER | ? ] -> [ ICE SNOW_COVER | SNOW_BELOW_WATER STOP ]
DOWN [ EXIT NO SNOW_COVER | NO SNOW_BELOW_WATER ] -> [ EXIT SNOW_COVER | SNOW_BELOW_WATER STOP ]

LATE UP [ @ | SNOW_COVER ] -> [ @ | SNOW_COVER_DOWN ]
LATE DOWN [ SNOW_COVER_DOWN | NO @ ] -> [ SNOW_COVER | ]
UP [ SNOW | NO SNOW NO SNOW_COVERS ] -> [ SNOW | SNOW_COVER ]
DOWN [ SNOW NO SNOW_BORDER | NO SNOWS ] -> [ SNOW SNOW_BORDER | ]

( Crate sprite )
LATE DOWN [ CRATE_TOP | NO CRATE ] -> [ | ]
LATE UP [ CRATE | NO CRATE_TOP ] -> [ CRATE | CRATE_TOP ]

( Stone sprite )
UP [ STONE | NO STONE_COVER ] -> [ STONE | STONE_COVER ]

( Gate sprites )
LATE UP [ GateBlue   | NO GateBlueTop   ] -> [ GateBlue   | GateBlueTop ]
LATE UP [ GateYellow | NO GateYellowTop ] -> [ GateYellow | GateYellowTop ]
LATE UP [ GateGreen  | NO GateGreenTop  ] -> [ GateGreen  | GateGreenTop ]
LATE UP [ GateRed    | NO GateRedTop    ] -> [ GateRed    | GateRedTop ]

LATE DOWN [ GATE_TOP | No GATE ] -> [ | ]

( Holes )
UP [ HOLES | HOLES ] -> [ HOLE_DOUBLE | HOLES ]

(-
 - Logic
)
( Crates )
[ > @ | CRATE | HOLES       ] -> [   @ |         | HOLE_FILLED ] sfx4
[ > @ | CRATE | OBSTACLE    ] -> [   @ |   CRATE | OBSTACLE ] sfx0
[ > @ | CRATE | NO FloorWet ] -> [ > @ | > CRATE | ] sfx1

UP    [ > @ | CRATE | FloorWet ] -> [ @ | | CRATE U X FloorWet ] sfx1
DOWN  [ > @ | CRATE | FloorWet ] -> [ @ | | CRATE D X FloorWet ]
LEFT  [ > @ | CRATE | FloorWet ] -> [ @ | | CRATE L X FloorWet ] sfx1
RIGHT [ > @ | CRATE | FloorWet ] -> [ @ | | CRATE R X FloorWet ] sfx1

UP    ['][ CRATE U X | HOLES ] -> ['][ | HOLE_FILLED ] sfx4
DOWN  ['][ CRATE D X | HOLES ] -> ['][ | HOLE_FILLED ] sfx4
LEFT  ['][ CRATE L X | HOLES ] -> ['][ | HOLE_FILLED ] sfx4
RIGHT ['][ CRATE R X | HOLES ] -> ['][ | HOLE_FILLED ] sfx4

UP    ['][ CRATE U X | OBSTACLE ] -> ['][ CRATE | OBSTACLE ] sfx3
DOWN  ['][ CRATE D X | OBSTACLE ] -> ['][ CRATE | OBSTACLE ] sfx3
LEFT  ['][ CRATE L X | OBSTACLE ] -> ['][ CRATE | OBSTACLE ] sfx3
RIGHT ['][ CRATE R X | OBSTACLE ] -> ['][ CRATE | OBSTACLE ] sfx3

UP    ['][ CRATE U X | FloorWet ] -> ['][ | CRATE U Y FloorWet ] sfx2
DOWN  ['][ CRATE D X | FloorWet ] -> ['][ | CRATE D Y FloorWet ] sfx2
LEFT  ['][ CRATE L X | FloorWet ] -> ['][ | CRATE L Y FloorWet ] sfx2
RIGHT ['][ CRATE R X | FloorWet ] -> ['][ | CRATE R Y FloorWet ] sfx2

UP    ['][ CRATE U X | GATEDOWN ] -> ['][ | CRATE GATEDOWN ]
DOWN  ['][ CRATE D X | GATEDOWN ] -> ['][ | CRATE GATEDOWN ]
LEFT  ['][ CRATE L X | GATEDOWN ] -> ['][ | CRATE GATEDOWN ]
RIGHT ['][ CRATE R X | GATEDOWN ] -> ['][ | CRATE GATEDOWN ]

UP    ['][ CRATE U X | BUTTON ] -> ['][ | CRATE BUTTON ]
DOWN  ['][ CRATE D X | BUTTON ] -> ['][ | CRATE BUTTON ]
LEFT  ['][ CRATE L X | BUTTON ] -> ['][ | CRATE BUTTON ]
RIGHT ['][ CRATE R X | BUTTON ] -> ['][ | CRATE BUTTON ]

UP    ['][ CRATE U X | FLOOR ] -> ['][ | CRATE FLOOR ]
DOWN  ['][ CRATE D X | FLOOR ] -> ['][ | CRATE FLOOR ]
LEFT  ['][ CRATE L X | FLOOR ] -> ['][ | CRATE FLOOR ]
RIGHT ['][ CRATE R X | FLOOR ] -> ['][ | CRATE FLOOR ]

UP    ['][ CRATE U X | HOLE_FILLED ] -> ['][ | CRATE HOLE_FILLED FLOOR ]
DOWN  ['][ CRATE D X | HOLE_FILLED ] -> ['][ | CRATE HOLE_FILLED FLOOR ]
LEFT  ['][ CRATE L X | HOLE_FILLED ] -> ['][ | CRATE HOLE_FILLED FLOOR ]
RIGHT ['][ CRATE R X | HOLE_FILLED ] -> ['][ | CRATE HOLE_FILLED FLOOR ]

['][ CRATE Y ] -> ['][ CRATE X ]

( Buttons and gates )
[ INVERTER | GATE NO Z ] -> [ | GATE Z ]

[ ButtonBlue CRATE   ] [ GateBlue NO Z ]   -> [ ButtonBlue CRATE   ] [ GateBlueDown NO Z ]
[ ButtonYellow CRATE ] [ GateYellow NO Z ] -> [ ButtonYellow CRATE ] [ GateYellowDown NO Z ]
[ ButtonGreen CRATE  ] [ GateGreen NO Z ]  -> [ ButtonGreen CRATE  ] [ GateGreenDown NO Z ]
[ ButtonRed CRATE    ] [ GateRed NO Z ]    -> [ ButtonRed CRATE    ] [ GateRedDown NO Z ]

[ ButtonBlue NO CRATE   ] [ GateBlueDown NO Z ]   -> [ ButtonBlue   ] [ GateBlue NO Z ]
[ ButtonYellow NO CRATE ] [ GateYellowDown NO Z ] -> [ ButtonYellow ] [ GateYellow NO Z ]
[ ButtonGreen NO CRATE  ] [ GateGreenDown NO Z ]  -> [ ButtonGreen  ] [ GateGreen NO Z ]
[ ButtonRed NO CRATE    ] [ GateRedDown NO Z ]    -> [ ButtonRed    ] [ GateRed NO Z ]

[ ButtonBlue Crate   ] [ GateBlueDown Z ]   -> [ ButtonBlue CRATE   ] [ GateBlue Z ]
[ ButtonYellow Crate ] [ GateYellowDown Z ] -> [ ButtonYellow CRATE ] [ GateYellow Z ]
[ ButtonGreen Crate  ] [ GateGreenDown Z ]  -> [ ButtonGreen CRATE  ] [ GateGreen Z ]
[ ButtonRed Crate    ] [ GateRedDown Z ]    -> [ ButtonRed CRATE    ] [ GateRed Z ]

[ ButtonBlue NO CRATE   ] [ GateBlue Z ]   -> [ ButtonBlue   ] [ GateBlueDown Z ]
[ ButtonYellow NO CRATE ] [ GateYellow Z ] -> [ ButtonYellow ] [ GateYellowDown Z ]
[ ButtonGreen NO CRATE  ] [ GateGreen Z ]  -> [ ButtonGreen  ] [ GateGreenDown Z ]
[ ButtonRed NO CRATE    ] [ GateRed Z ]    -> [ ButtonRed    ] [ GateRedDown Z ]

RANDOM [ GATE CRATE | NO @ NO OBSTACLE ] -> [ GATE | CRATE ]

( Win condition )
[ > PLAYER | EXIT   ] [ COUNTER ] -> [   PLAYER | EXIT X ] [ ] sfx6
[ > PLAYER | EXIT X ]             -> [ > PLAYER | EXIT Y ]

( Counter )
LATE [ EXIT X ] [ | | DIVIDER | | ] -> [ EXIT X ][ STOPPED | STOPPED | DIVIDER STOPPED | STOPPED | STOPPED ]

[ MOVING @ ] [ COUNTER NO TIMER_T ] -> [ MOVING @ ] [ COUNTER Y ]

LATE ['][ COUNTER TIMER_3 ] -> ['][ COUNTER X ]
LATE ['][ COUNTER TIMER_2 ] -> ['][ COUNTER TIMER_3 ]
LATE ['][ COUNTER TIMER_1 ] -> ['][ COUNTER TIMER_2 ]
LATE ['][ COUNTER TIMER_0 ] -> ['][ COUNTER TIMER_1 ]
LATE ['][ COUNTER R       ] -> ['][ COUNTER TIMER_0 ]
LATE ['][ COUNTER L       ] -> ['][ COUNTER R ]
LATE ['][ COUNTER D       ] -> ['][ COUNTER L ]
LATE ['][ COUNTER U       ] -> ['][ COUNTER D ]
LATE ['][ COUNTER Z       ] -> ['][ COUNTER U ]
LATE ['][ COUNTER Y       ] -> ['][ COUNTER Z ]

LATE RIGHT [ NUM NO X | COUNTER X ] -> [ NUM X | COUNTER Y ]
LATE RIGHT [ NUM | DIVIDER | N5 | N9 ] -> [ NUM X | DIVIDER | N0 | N0 ]

STARTLOOP
LATE [ N0 X ] -> [ N1 ]
LATE [ N1 X ] -> [ N2 ]
LATE [ N2 X ] -> [ N3 ]
LATE [ N3 X ] -> [ N4 ]
LATE [ N4 X ] -> [ N5 ]
LATE [ N5 X ] -> [ N6 ]
LATE [ N6 X ] -> [ N7 ]
LATE [ N7 X ] -> [ N8 ]
LATE [ N8 X ] -> [ N9 ]
LATE LEFT [ N9 X | NUM ] -> [ N0 | NUM X ]
ENDLOOP

==============
WINCONDITIONS
==============
Some Y on EXIT

=======
LEVELS
=======
.............
."1...00:00µ.
.............
..ú¿¿¿¿¿¿¿æ..
.?ø_______î≥≥
.?__w___!_í`e
.?_®w______?.
.?__}__n___?.
.?__wwww___?.
.?__wwwww*_?.
.?_____ww__?.
.?˚_______¬?.
..«»»»»»»»∏..
.............

......................
."2............00:00µ.
......................
..ú????????????????æ..
.?ø________________î≥≥
.?___#____!_cf___#_í`e
.?__œ¨ff´___ff∑¨f___?.
.?__#_ff#_f¨f_#_ff__?.
.?_____ffff___fffc__?.
.?__fff_ff¥ffff_f#__?.
.?__®#f†ff_ff#ffff__?.
.?˚________________¬?.
..«»»»»»»»»»»»»»»»»∏..
......................

...............
."3.....00:00µ.
...............
..ú?????????æ..
.?ø_____!___î≥≥
.?__®_______í`e
.?_wwwwww#w__?.
.?_wwww#www__?.
.?_#wwwwwww__?.
.?_www#wwww__?.
.?_w#wwwwww__?.
.?_wwwwwww#__?.
.?_ww#nw#ww__?.
.?˚_________¬?.
..«»»»»»»»»»∏..
...............

......................
."4............00:00µ.
......................
..ú????????????????æ..
.?ø________________î≥≥
.?__www____________í`e
.?__w}wwwwwwn_______?.
.?__w£wwwwwww_______?.
.?__wwwwwwww…__n#ww_?.
.?__wwwww}ww£__wwww_?.
.?__www…w£www__#´ww_?.
.?_®…£w£wwwww__ww#w_?.
.?__wwwwww…£w__wwww_?.
.?__wwwwwwwwww_w#ww_?.
.?__ww…w£ww£}w_wwwœ_?.
.?__ww£w}wwwww______?.
.?______www______!__?.
.?˚________________¬?.
..«»»»»»»»»»»»»»»»»∏..
......................

.............
."5...00:00µ.
.............
..ú¿¿¿¿¿¿¿æ..
.?ø_______î≥≥
.?___n__!_í`e
.?___wn____?.
.?___www___?.
.?_®˛wçwwn_?.
.?˚_______¬?.
..«»»»»»»»∏..
.............

...............
."6.....00:00µ.
...............
..ú¿¿¿¿¿¿¿¿¿æ..
.?ø_________ô?.
.?_!_ww;#____?.
.?__wçwnw#w´_?.
.?_®wçw}wnww_?.
.?__wwwwwwww_?.
.?_#wwww#∑w__?.
.?_nwç;wwww__?.
.?_www£wwnw_î≥≥
.?__ççç_____í`e
.?˚_________¬?.
..«»»»»»»»»»∏..
...............