Contract used to register hashes of files to proof the original authoring of them.

ProofOfAuthoring.sol

pragma solidity ^0.4.0;

/*
Proof of authoring 

Contract used to register hashes of files to proof the original authoring of them.
Owner can transfer the ownership. 
Contract accept donation to documents registereds.

Written by Ricardo Guilherme Schmidt <[email protected]>
*/

contract ProofOfAuthoring  {

    event DocumentRegister(address _owner, bytes32 _hash, uint _time);
    event Transfer(bytes32 _hash, address _newOwner);
    event Donate(bytes32 _hash, address _donator, uint _value);
    
    struct Document{
        address owner;
        uint time;
    }
    
    modifier only_owner (bytes32 _hash){
        if(documents[_hash].owner != msg.sender) throw;
        _;
    }
    
    modifier owned (bytes32 _hash){
        if(documents[_hash].owner == 0x0) throw;
        _;
    }
    
    modifier not_owned (bytes32 _hash){
        if(documents[_hash].owner != 0x0) throw;
        _;
    }
    
    mapping(bytes32 => Document) public documents;

    function () {
        throw;
    }
    
    function registerDocument(bytes32 _hash) not_owned(_hash){
        registerDocumentTo(msg.sender, _hash);
    }    
    
    function registerDocumentTo(address _owner, bytes32 _hash) not_owned(_hash){
        documents[_hash] = Document({owner: _owner, time: block.timestamp});
        DocumentRegister(_owner, _hash, block.timestamp);
    }

    function transfer(bytes32 _hash, address _newOwner) only_owner(_hash){
        documents[_hash].owner = _newOwner;
        Transfer(_hash,_newOwner);
    }
    
    function donate(bytes32 _hash) payable owned(_hash){
        if(documents[_hash].owner.send(msg.value))
            Donate(_hash,msg.sender,msg.value);
    }
}