SparQL queries for K-Samsök

count_images_without_license_by_org.rq

SELECT DISTINCT ?sOrg (COUNT(?item) AS ?count) WHERE {
  OPTIONAL { ?item <http://kulturarvsdata.se/ksamsok#serviceOrganization> ?sOrg . }
  ?item <http://kulturarvsdata.se/ksamsok#image> ?image .
  FILTER NOT EXISTS { ?image <http://kulturarvsdata.se/ksamsok#mediaLicenseUrl> ?license }
} GROUP BY ?sOrg

count_unique_color_values.rq

SELECT ?color (COUNT(?color) AS ?count) WHERE {
  ?item <http://kulturarvsdata.se/ksamsok#itemColor> ?color .
}
GROUP BY ?color
ORDER BY DESC(?count)

explore_rok_stenen.rq

PREFIX soch: <http://kulturarvsdata.se/ksamsok#>
PREFIX fmis: <http://kulturarvsdata.se/raa/fmi/>

SELECT ?p WHERE {
  fmis:10253101330001 ?p ?o .
}

get_all_soch_classes.rq

prefix owl: <http://www.w3.org/2002/07/owl#>

SELECT DISTINCT * WHERE {
  ?class a owl:Class .
  FILTER(STRSTARTS(STR(?class), 'http://kulturarvsdata.se/ksamsok#'))
}

get_all_soch_object_properties.rq

PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT DISTINCT ?property WHERE {
  ?property a owl:ObjectProperty .
}

get_all_sources_kungshogarna.rq

PREFIX soch: <http://kulturarvsdata.se/ksamsok#>
PREFIX fmis: <http://kulturarvsdata.se/raa/fmi/>

SELECT ?refs WHERE {
  fmis:10028201230001 soch:itemDescription ?description_node .
  ?description_node soch:type "Referenser" .
  ?description_node soch:desc ?refs .
}

item_with_mediaType_containing_the_sting_image.rq

SELECT ?item WHERE {
  ?item <http://kulturarvsdata.se/ksamsok#image> ?image .
  ?image <http://kulturarvsdata.se/ksamsok#mediaType> ?mediaType . 
  FILTER REGEX(STR(?mediaType), "image")
}

license_usage.rq

SELECT ?license (COUNT(?license) AS ?count) WHERE {
  ?item <http://kulturarvsdata.se/ksamsok#image> ?o .
  ?o <http://kulturarvsdata.se/ksamsok#mediaLicenseUrl> ?license
}
GROUP BY ?license

list_items_without_license_by_org.rq

SELECT DISTINCT ?item WHERE {
  ?item <http://kulturarvsdata.se/ksamsok#serviceOrganization> "upmu" .
  ?item <http://kulturarvsdata.se/ksamsok#image> ?image .
  FILTER NOT EXISTS { ?image <http://kulturarvsdata.se/ksamsok#mediaLicenseUrl> ?license }
}

media_type_usage.rq

SELECT ?mediaType (COUNT(?mediaType) AS ?count) WHERE {
  ?item <http://kulturarvsdata.se/ksamsok#mediaType> ?mediaType .
}
GROUP BY ?mediaType
ORDER BY DESC(?count)