ConfigLoader.coffee

define ["underscore", "view/elements/DrawerElement"], (_, DrawerElementView) ->

	class ConfigurationLoader
		constructor: ->
			_.bindAll @
			@load()
		getConfigId: ->
			regex = ///
				(.+?)		# Match anything before config/
				config/		# Match "config/"
				([0-9]+)	# Match any number from 0 to infinity and save it as $2
				/?		# optionally match a trailing slash
			///

			location.hash.replace( regex, "$2" )
		getJsonPath: ->
			GLOBAL.BASE_URL + GLOBAL.JSON_TEMPLATES_DIR + "/template#{ @getConfigId() }.json"
		load: ->
			$.getJSON( @getJsonPath() ).then @parseConfiguration
		parseConfiguration: (data) ->
			@buildContainer container for container in data.nodes
			return
		getContainerView: (name) ->
			model = app.config.elements.findWhere { name:name }
			if model then return new DrawerElementView model:model
			else return false
		getElementPosition: (el) ->
			unless @artboardOffset? then @artboardOffset = app.artboard.$el.offset().left
			return { x: el.position_x + @artboardOffset, y: el.position_y }
		buildContainer: (container) ->
			view = @getContainerView container.element_name
			position = @getElementPosition container
			$(document).trigger "ahrengot/spawn_element", [view, position]

	return ConfigurationLoader