Join multiple MOV files into a single MP4 without reencoding (useful for video cameras that split files every 4GB)

joinmov.bat

@echo off

if "%1"=="" (
	echo usage example: join.bat video1.mov video2.mov video3.mov
	echo this will create joined.mp4 in the same directory
	exit /B 1
)

ffmpeg -version >nul 2>&1 || (
	echo ffmpeg missing, install from http://ffmpeg.zeranoe.com/builds/
	exit /B 1
)

set filenamesconcat=
set pipe=:

:convertfile
if "%1"=="" goto convertfileend

if not "%filenamesconcat%"=="" (
	set "filenamesconcat=%filenamesconcat%%pipe%"
)
set filenamesconcat=%filenamesconcat%%1.ts

ffmpeg -i "%1" -c:v copy -c:a aac -strict -2 "%1.mp4"
ffmpeg -i "%1.mp4" -c copy -vbsf h264_mp4toannexb "%1.ts"
del "%1.mp4"
shift
goto convertfile

:convertfileend
ffmpeg -i concat:"%filenamesconcat::=|%" -c copy -absf aac_adtstoasc "joined.mp4"

for %%A in (%*) do (
	del "%%A.ts"
)

Derived from Jim Watters' ConCatMovies.bat, which has a broken download link (even after logging in), so I wrote my own.