Command-line window replacement (not fully functional)

command_line_window.vim

nnoremap <silent> q: :call <SID>Open(':')<cr>

function! s:Open(type) abort
  botright 7new

  let b:type = a:type

  call s:Redraw(a:type)
  normal! G

  setlocal buftype=prompt
  setlocal filetype=vim
  call prompt_setprompt(bufnr(), ':')
  call prompt_setcallback(bufnr(), function('s:ExecutePrompt'))

  nnoremap <buffer><silent> <cr> :exe getline('.')<cr>
  nnoremap <buffer><silent> dd :call <SID>Delete()<cr>
endfunction

function! s:Redraw(type) abort
  let saved_view = winsaveview()
  defer winrestview(saved_view)

  let limit = histnr(a:type)

  let lines   = []
  let mapping = {}

  for number in range(1, limit)
    let entry = histget(a:type, number)
    if entry != ''
      call add(lines, entry)
      let mapping[len(lines)] = number
    endif
  endfor

  let b:line_mapping = mapping

  %delete _
  call append(0, lines)
  set nomodified
endfunction

function! s:Delete() abort
  call histdel(b:type, b:line_mapping[line('.')])
  delete _
  call s:Redraw(b:type)
endfunction

function! s:ExecutePrompt(text) abort
  exe a:text
  call histadd(b:type, a:text)
  call s:Redraw(b:type)
endfunction