I have an extended coding grammar — a "code mode" that extends my normal coding grammar with shorter commands closer to the syntax of the language. I've included my standard custom grammar as well

coding__code_mode__typescript.talon

tag: user.code_mode
code.language: typescript
code.language: typescriptreact
-
# Keywords
export: "export "
export from file: user.insert_between("export * from '", "';")
import from package <user.text>$:
    target = user.formatted_text(text or "", 'DASH_SEPARATED')
    user.insert_between("import {{ ", " }} from '{target}';")
import from package$: user.insert_between("import {{  }} from '", "';")

const <user.text>$:
    name = user.formatted_text(text, 'PRIVATE_CAMEL_CASE')
    user.insert_between("const {name} = ", ";")
as const: "as const "
satisfies [<user.text>]:
    constraint = user.formatted_text(text or "", 'PUBLIC_CAMEL_CASE')
    "satisfies {constraint}"
type$: "type "
const: "const "
async: "async "
await: "await "
return: "return "
extends: "extends "
make throw: user.insert_between("throw new Error(`", "`)")

# (funk | function) [<user.text>]$:
#     name = user.formatted_text(text or "", 'PRIVATE_CAMEL_CASE')
#     user.insert_between("function {name}(", ") {{}}")

# Types
make (object | odder) type <user.text>$:
    "type {user.formatted_text(text, 'PUBLIC_CAMEL_CASE')} = {"
    key(enter)
make type <user.text>:
    txt = text or ""
    "type {user.formatted_text(txt, 'PUBLIC_CAMEL_CASE')} = "

# Control Flow
for each [<user.text>] of [<user.text>]:
    var = text_1 or ""
    obj = text_2 or ""
    varf = user.formatted_text(var, 'PRIVATE_CAMEL_CASE')
    insert("for (const {varf} of {user.formatted_text(obj, 'PRIVATE_CAMEL_CASE')}) {{}}")
for each [<user.text>] in [<user.text>]:
    var = text_1 or ""
    obj = text_2 or ""
    varf = user.formatted_text(var, 'PRIVATE_CAMEL_CASE')
    insert("for (const {varf} in {user.formatted_text(obj, 'PRIVATE_CAMEL_CASE')}) {{}}")
make fork: user.insert_between("if (", ")")
[make] branch$: user.insert_between("if (", ") {{")
[make] branch that$:
    text = edit.selected_text()
    user.insert_between("if (", ") {{{text}}}")
make try$: user.insert_between("try {{", "}} catch (error) {{}}")
make try that$:
    text = edit.selected_text()
    user.insert_between("try {{{text}}} catch (error) {{", "}}")
while loop: user.insert_between("while (", ") {{")

# Operators
arrow funk: user.insert_between("(", ") => ")
empty (lam | lambda | arrow): "() => "
make adder [<user.number_prose_unprefixed>]$: " += {number_prose_unprefixed or ''};"
make ander: " && "
make order: " || "

# Comments
(dog | dock) string:
    "/**"
    key(enter)
mint: "// "

# Testing
deno test: user.insert_between("Deno.test('", "', () => {{}});")
deno test async: user.insert_between("Deno.test('", "', async ({{ step }}) => {{}});")
deno step: user.insert_between("await step('", "', async () => {{}});")
make test describe: user.insert_between("describe('", "', () => {{}});")
make test case: user.insert_between("it('", "', () => {{}});")
test expect: user.insert_between("expect(", ");")
too equal:
    edit.right()
    user.insert_between(".toEqual(", ")")

tag(): user.cursorless_use_community_snippets

coding__general.talon

app: vscode
-
assign: " = "
make arg:
  user.cursorless_x_custom_command("post arg")
  insert(", ")

coding__typescript.talon

code.language: typescript
code.language: typescriptreact
code.language: javascript
code.language: javascriptreact
-
interpol: user.insert_between("${{", "}}")
make deno step: user.insert_between("await step('", "', async () => {{}})")
make deno test: user.insert_between("Deno.test('", "', async ({{ step }}) => {{}})")
make describe: user.insert_between("describe('", "', () => {{}});")
make test case: user.insert_between("it('", "', () => {{}});")
make expect: user.insert_between("expect(", ");")
make comment: "// "
make console log: user.insert_between("console.log(", ");")
make promise: insert("Promise")
make void: "void"
make record: user.insert_between("Record<string, ", ">")
make date now: "Date.now()"
make immediately invoked async: user.insert_between("(async () => {{", "}})()")
make higher kinded type issue: "// @ts-expect-error higher-kinded type issue: https://github.com/microsoft/TypeScript/issues/44875"
make zod [<user.word>]: insert("z.{word}")

tag(): user.cursorless_use_community_snippets