Num.ls

!Num.ls

Num.ls

area.ls

# Number -> Number -> Number
triangle-area = (base, height) --> base * height |> half

# Number -> Number -> Number 
rectangle-area = (width, height) --> width * height

# Number -> Number
square-area = (side) -> side * side

# Number -> Number -> Number
parallelogram-area = (base, height) --> base * height

# Number -> Number -> Number -> Number
trapezoid-area = (upper-base, lower-base, height) --> (upper-base + lower-base) * height |> half

# Number -> Number
circle-area = (radius) -> pi * radius * radius

C.ls

# Number -> Number -> Number
C = (n, r) -->
  | r == 0 => 1
  | r == 1 => n
  | n == r => 1
  | (half n) < r => C n, n - r
  | _ => (P n, r) / (factorial r)

distance.ls

# Number -> Number -> Number
distance1 = (x1, x2) --> x1 - x2 |> abs

# Number -> Number -> Number -> Number -> Number
distance2 = (x1, y1, x2, y2) --> (distance1 x1, x2) ^ 2 + (distance1 y1, y2) ^ 2 |> sqrt

# Number -> Number -> Number -> Number -> Number -> Number -> Number
distance3 = (x1, y1, z1, x2, y2, z2) --> (distance2 x1 y1 x2 y2) ^ 2 + (distance1 z1 z2) ^ 2 |> sqrt

divisible-by.ls

# Number -> Number -> Boolean
divisible-by = (x, n) --> x % n == 0

exponential.ls

# Number -> String
exponential = (.toExponential!)

factorial.ls

# Number -> Number
factorial = (n) -> [1 to n] |> product

factors.ls

# Number -> [Number]
factors = (n) -> [x for x from 1 to n when n `divisible-by` x]

half.ls

# Number -> Number
half = (/ 2)

herons-formula.ls

# Number -> Number -> Number -> Number
herons-formula = (a, b, c) -->
  s = a + b + c |> half
  s * (s - a) * (s - b) * (s - c) |> sqrt

P.ls

# Number -> Number -> Number
P = (n, r) --> [n - r + 1 to n] |> product

random.ls

# Number -> Number -> Number
random = (from, to) -->　floor(Math.random! * (to - from + 1)) + from