Reverse polish notation arithmetic interpreter in JQ

arithmetic.jq

def tokens:
  split(" ") | map(select(length > 0));

def isnum:
  test("^-?([0-9]+(\\.[0-9]+)?)$");

def evaluate:
  def eval($tokens):
    if ($tokens | length) == 0 then
      error("ending unexpected")
    else
      ($tokens[0]) as $f |
      if ($f | isnum) then
        [($f | tonumber), ($tokens[1:])]
      elif ($f | IN("+","-","*","/")) then
        eval($tokens[1:]) as [$x, $r] |
        eval($r) as [$y, $rest] |
        (if   $f == "+" then $x + $y
         elif $f == "-" then $x - $y
         elif $f == "*" then $x * $y
         else
           if $y == 0 then
             error("division by zero")
           else
             $x / $y
           end
         end) as $val
         | [$val, $rest]
      else
        error("todo: \($f)")
      end
    end;
  ( . | tokens ) as $tokens
  | eval($tokens) as [$result, $rest]
  | if ($rest | length) > 0
    then error("result value: \($result)\nremaining tokens: \($rest)")
    else $result
    end;

evaluate

echo "+ 2 2" | jq -Rr -f polish.jq
# 4
echo "+ - 3 2 - 2 1" | jq -Rr -f polish.jq
# 2
echo "+ * 3 2 - 2 1" | jq -Rr -f polish.jq
# 7
echo "* 3 / 4 2" | jq -Rr -f polish.jq
# 6