VBA: get RegEx matches as simple Array, using /pattern/[flags] syntax

RegExMatches.vbs

' About: https://www.reddit.com/r/vba/comments/p8i523/code_vba_function_get_regex_matches_as_array/
Function matches(ByVal text As String, pattern As String) As Variant()
    Dim allMatches As Object, flagMatches As Object
    Dim RE As Object, FRE As Object, fGlobal As Boolean, fIgnoreCase As Boolean, fMultiLine As Boolean
    Set RE = CreateObject("vbscript.regexp")
    ' Check for slash delim syntax with optional flags, like /pattern/[flags]
    Set FRE = CreateObject("vbscript.regexp")
    FRE.pattern = "^\/(.+)\/([gmi]*)$"
    FRE.IgnoreCase = True
    Set flagMatches = FRE.Execute(pattern)
    If flagMatches.Count >= 1 Then
        pattern = flagMatches.Item(0).submatches(0)
        If InStr(flagMatches.Item(0).submatches(1), "g") >= 1 Then fGlobal = True
        If InStr(flagMatches.Item(0).submatches(1), "m") >= 1 Then fMultiLine = True
        If InStr(flagMatches.Item(0).submatches(1), "i") >= 1 Then fIgnoreCase = True
    End If
    ' Apply properties. If not set, Boolean flags default to FALSE
    RE.pattern = pattern
    RE.Global = fGlobal
    RE.MultiLine = fMultiLine
    RE.IgnoreCase = fIgnoreCase
    Set allMatches = RE.Execute(text)
    
    If allMatches.Count > 0 Then
        If fGlobal Then
            Dim i As Integer, m() As Variant
            ReDim m(allMatches.Count - 1)
            For i = 0 To allMatches.Count - 1
                m(i) = toArray(allMatches.Item(i).submatches) ' Add all captured groups
                ArrayInsert m(i), allMatches.Item(i).Value, 0 ' Set the whole matched content as (0), offset first matching group as (1), etc
            Next i
            matches = m
        Else
            matches = toArray(allMatches.Item(0).submatches)
            matches = ArrayInsert(matches, allMatches.Item(0).Value, 0)
        End If
    End If
End Function

' Helper functions I found useful. You may have to consolidate/integrate them with your existing library/mudules
Function toArray(a As Object) As Variant
    Dim r() As Variant
    If IsObject(a) And a.Count > 0 Then
         ReDim r(a.Count - 1)
         Dim i As Integer
         For i = 0 To a.Count - 1
             If hasProperty(a, "Items") Then
                 r(i) = a.Items(i)
             Else
                 r(i) = a(i)
             End If
         Next i
    End If
    toArray = r
End Function

Function hasProperty(obj As Variant, prop As String) As Boolean
    hasProperty = False
    Dim t As Variant
    If IsObject(obj) Then
        On Error GoTo endFunc
        t = CallByName(obj, prop, VbGet)
    End If
endFunc:
End Function

Function getProperty(obj As Variant, prop As String) As Variant
    getProperty = Nothing
    On Error GoTo endFunc
    getProperty = CallByName(obj, prop, VbGet)
endFunc:
End Function

Function ArrayInsert(ByRef a As Variant, NewVal As Variant, Optional index As Integer = -1) As Variant
    Dim i As Long, u As Long
    If Not is_Empty(a) Then
        ReDim Preserve a(0 To UBound(a) + 1 - LBound(a))
        If index = -1 Then index = UBound(a)
        For i = UBound(a) To index + 1 Step -1
            a(i) = a(i - 1)
        Next i
        a(index) = NewVal
    Else
        ReDim a(0)
        a(0) = NewVal
    End If
    ArrayInsert = a
End Function

Public Function is_Empty(ByRef a As Variant) As Boolean
    is_Empty = True
    On Error Resume Next
    is_Empty = Not IsNumeric(UBound(a))
    On Error GoTo 0
End Function