This gist contains a PKGBUILD for the flite package on Arch Linux. Fixed to prevent build errors on Arch.

flite-PKGBUILD

# Maintainer: Dennis Mungai <[email protected]>

pkgname=flite
pkgver=1.9.0
pkgrel=1
pkgdesc="A lighweight speech synthesis engine (text to speech)"
arch=('i686' 'x86_64')
url="http://cmuflite.org"
license=('custom')
depends=('alsa-lib')
options=('strip' '!buildflags')
source=(http://festvox.org/bard/${pkgname}-${pkgver}-current.tar.bz2)
md5sums=('ff3e394a2ea6ef31ca93e6f25c6cbcae')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}-current"
  sed '/^#VOXES.*$/d; s/+//g; s/usenglish/&\nVOXES = cmu_us_kal16 cmu_us_slt/' config/android.lv >config/archlinux.lv
  sed -i '/$(INSTALL) -m 755 $(BINDIR)\/flite_time $(DESTDIR)$(INSTALLBINDIR)/d' main/Makefile
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}-current"
  ./configure --prefix=/usr --enable-shared --with-audio=alsa
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}-current"
  make prefix="${pkgdir}/usr" install
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

Fixes annoying build errors in flite's AUR package. Build and test. Works with Kismet as the voice synthesis engine.