Cocos2dx build.gradle

build.gradle

apply plugin: 'com.android.application'

android {
    compileSdkVersion 22
    buildToolsVersion "22.0.1"

    buildDir = 'bin'

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            signingConfig signingConfigs.release
        }
    }

    sourceSets {
        main {
            manifest.srcFile 'proj.android/AndroidManifest.xml'
            assets.srcDirs = ['Resources']
            java.srcDirs = ['proj.android/src', 'cocos2d/cocos2dx/platform/android/java/src']
            res.srcDirs = ['proj.android/res', 'cocos2d/cocos2dx/platform/android/java/res']
            jni.srcDirs = ['proj.android/jni', 'Classes']
            jniLibs.srcDirs = ['proj.android/libs']
        }
    }
    
    lintOptions {
         abortOnError false
    }

    // stop default native builder
    task clearJni << {
        sourceSets.main.jni.srcDirs = []
    }

    task ndkBuild(type:Exec, dependsOn:clearJni) {
        workingDir 'proj.android'
        commandLine './build_native.sh'
    }

    // cocos2dx 2.2.x doesn't support gradle for this reason add sources and resources
    // but do this dynamically instead your project will looks horible in Android Studio
    task addCocos2dxSources << {
	    sourceSets.main.assets.srcDirs += 'cocos2d/cocos2dx/platform/android/java/assets'
        sourceSets.main.java.srcDirs += 'cocos2d/cocos2dx/platform/android/java/src'
        sourceSets.main.res.srcDirs += 'cocos2d/cocos2dx/platform/android/java/res'
    }
    addCocos2dxSources.dependsOn ndkBuild

    tasks.withType(JavaCompile) {
        compileTask -> compileTask.dependsOn addCocos2dxSources
    }

    task cleanExtra(type: Delete) {
        delete "${project.buildDir}"
    }

    clean.dependsOn(cleanExtra)
}