Scoping of `self` demo

1-output.txt

$ nix build .#nixosConfigurations.demo.config.system.build.toplevel
trace: I'm Mr. Meeseeks! Existence is pain!
trace: I'm Mr. Meeseeks! Look at me!

externalModule.nix

{ self }:
{ config, lib, ... }: {
  system.nixos.tags = [ (self.lib.doSomeStuff "Existence is pain!") ];
}

flake.nix

{
  inputs.nixpkgs.url = "nixpkgs";
  outputs = { self, nixpkgs }: {
    nixosConfigurations.demo = nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      modules = [
        self.nixosModules.sameFile
        self.nixosModules.externalFile
        {
          boot.isContainer = true; # Hack to have an easy time building
          system.stateVersion = "23.11";
        }
      ];
    };

    nixosModules = {
      sameFile = { config, lib, ... }: {
        system.nixos.tags = [ (self.lib.doSomeStuff "Look at me!") ];
      };

      externalFile = import ./externalModule.nix { inherit self; };
    };

    lib.doSomeStuff = x: builtins.trace "I'm Mr. Meeseeks! ${x}" "Mr.Mee";
  };
}