too many warnings

too_many_warnings.ex

  defp send_messages(msg_list, s, do_timer_reset) do
    if do_timer_reset do
      if s.acks != [] do
        ids = s.acks
        s = %{s | acks: []}
        log "adding acks: #{inspect ids}"
        msg_list = msg_list ++ [{TL.msgs_ack(ids), false}]
      end

      # if s.resends != [] do
      #   ids = s.resends
      #   s = %{s | resends: []}
      #   log "adding resends: #{inspect ids}"
      #   msg_list = msg_list ++ [{TL.msg_resend_req(ids), false}]
      # end

      :timer.cancel(s.ack_timer)
    end

    if length(msg_list) > 1 do
      {content_count, prev_msg_id, msg} = pack_messages(msg_list, 0, "", s.content_count, s.prev_msg_id)

      send_enc(seq_no(content_count, false), message_id(prev_msg_id + 8), content_count, msg, s)
    else
      {msg, is_content} = hd(msg_list)

      if is_content == true do
        send_enc(seq_no(s.content_count, true), message_id(s.prev_msg_id + 8), s.content_count + 1, msg, s)
      else
        send_enc(seq_no(s.content_count, false), message_id(s.prev_msg_id + 8), s.content_count, msg, s)
      end
    end
  end

No more warnings, and I guess it's a bit cleaner :)

  defp send_messages(msg_list, s, true) do
    {s, msg_list} =
      if s.acks != [] do
        log "adding acks: #{inspect s.acks}"
        {%{s | acks: []}, msg_list ++ [{TL.msgs_ack(s.acks), false}]}
      else
        {s, msg_list}
      end

      # if s.resends != [] do
      #   ids = s.resends
      #   s = %{s | resends: []}
      #   log "adding resends: #{inspect ids}"
      #   msg_list = msg_list ++ [{TL.msg_resend_req(ids), false}]
      # end

    :timer.cancel(s.ack_timer)

    send_messages(msg_list, s, false)
  end
  defp send_messages([{msg, true}], s, false) do
    send_enc(seq_no(s.content_count, true), message_id(s.prev_msg_id + 8), s.content_count + 1, msg, s)
  end
  defp send_messages([{msg, false}], s, false) do
    send_enc(seq_no(s.content_count, false), message_id(s.prev_msg_id + 8), s.content_count, msg, s)
  end
  defp send_messages(msg_list, s, false) do
    {content_count, prev_msg_id, msg} = pack_messages(msg_list, 0, "", s.content_count, s.prev_msg_id)
    send_enc(seq_no(content_count, false), message_id(prev_msg_id + 8), content_count, msg, s)
  end