Meme text in Haskell

squareText.hs

module Main where

import Control.Monad
import Data.List

newtype Indent = Indent { unIndent :: Int } deriving (Show, Eq)

squareText :: String -> Maybe String
squareText []   = Nothing
squareText [_]  = Nothing
squareText text = Just $ firstLine ++ middleLines ++ "\n" ++ lastLine
  where
    firstLine = intersperse ' ' text
    lastLine = intersperse ' ' $ reverse text
    padding = length firstLine - 2

    addLines s (a, b) = s ++ "\n" ++ [a] ++ replicate padding ' ' ++ [b]
    midText = tail $ init text
    middleLines = foldl' addLines [] (zip midText $ reverse midText)

indent :: Indent -> String -> String
indent (Indent padding) =
    (replicate padding ' ' ++) . foldr pad []
  where
    pad '\n' s = "\n" ++ replicate padding ' ' ++ s
    pad c s    = c:s

printSquareText :: Indent -> String -> IO ()
printSquareText width = maybe (putStrLn errorText) putStrLn
                      . fmap (indent width)
                      . squareText
  where
    errorText = "Not a valid square"

writeSquareText :: FilePath -> Indent -> String -> IO ()
writeSquareText f width = mapM_ (writeFile f)
                        . fmap (indent width)
                        . squareText

twoWay.hs

module Main where

twoWay :: String -> String
twoWay s = appendEveryElem horizSpace s
        ++ vertSpace
        ++ appendEveryElem vertSpace (drop 1 s)
  where
    horizSpace = " "
    vertSpace = "\n\n"

    -- Returns a new list with es after every element in l.
    appendEveryElem :: [a] -> [a] -> [a]
    appendEveryElem es l = do
        elem <- l
        elem:es

twoWayToFile :: FilePath -> String -> IO ()
twoWayToFile f = writeFile f . twoWay