The 'ClearBefore' monoid, adding the ability to clear a log generated by a Writer.

gistfile1.hs

-- ClearBefore.hs

module ClearBefore where

import Data.Monoid

data ClearBefore a = ClearBefore Bool a

instance Monoid a => Monoid (ClearBefore a) where
  mempty = ClearBefore False mempty
  mappend (ClearBefore f a) (ClearBefore False b) = ClearBefore f (mappend a b)
  mappend _                 x                     = x

runClearBefore :: ClearBefore a -> a
runClearBefore (ClearBefore _ a) = a

-- Main.hs

{-# LANGUAGE FlexibleContexts #-}

module Main (main) where

import ClearBefore
import Control.Applicative
import Control.Monad.Writer

tell_ :: MonadWriter (ClearBefore w) m => w -> m ()
tell_ = tell . ClearBefore False

clear :: (Monoid w, MonadWriter (ClearBefore w) m) => m ()
clear = tell $ ClearBefore True mempty

main :: IO ()
main = do
  log <- liftM runClearBefore $ execWriterT $ do
    tell_ "a"
    tell_ "b"
    clear
    liftIO $ putStrLn "within writer"
    tell_ "c"
    tell_ "d"

  putStrLn $ "log: " <> log