script to quickly install adb on windows machines

adb-installer.bat

@echo off
setlocal

echo ========================================
echo   INSTALANDO ADB
echo ========================================

set "ADB_DIR=C:\adb"
set "ZIP_FILE=%TEMP%\platform-tools.zip"

echo.
echo [1/5] Baixando...

powershell -Command "Invoke-WebRequest https://dl.google.com/android/repository/platform-tools-latest-windows.zip -OutFile '%ZIP_FILE%'"

if not exist "%ZIP_FILE%" (
    echo ERRO no download
    pause
    exit /b
)

echo OK

echo.
echo [2/5] Extraindo...

tar -xf "%ZIP_FILE%" -C "%TEMP%"

if not exist "%TEMP%\platform-tools\adb.exe" (
    echo ERRO na extracao
    pause
    exit /b
)

echo OK

echo.
echo [3/5] Movendo...

if exist "%ADB_DIR%" rmdir /s /q "%ADB_DIR%"
move "%TEMP%\platform-tools" "%ADB_DIR%"

echo OK

echo.
echo [4/5] Adicionando ao PATH...

setx PATH "%PATH%;%ADB_DIR%"

echo OK

echo.
echo [5/5] Testando...

"%ADB_DIR%\adb" version

echo.
echo FINALIZADO
echo Feche o terminal e abra novamente
pause