Output range adapters proof of concept

output_adapter.d

import std.range, std.traits, std.stdio, std.format, std.digest.sha;

auto demux(Output...)(Output sinks)
{
    static struct Demux
    {
        Output outs;
        this(Output outs)
        {
            this.outs = outs;
        }
        void put(E)(E el)
        {
            foreach(sink; outs)
            {
                sink.put(el);
            }
        }
    }
    return Demux(sinks);
}

auto converter(alias conv, Output)(Output range)
{
    static struct Adapter
    {
        Output sink;
        this(Output sink)
        {
            this.sink = sink;
        }
        void put(E)(E el)
        {
            sink.put(conv(el));
        }
    }
    return Adapter(range);
}

void main()
{
    SHA1 hasher;
    hasher.start();
    auto conv = converter!(x => cast(ubyte[])x)(&hasher);
    auto demuxed = demux( stdout.lockingTextWriter(), conv);
    formattedWrite(demuxed, "Hello, world!\n");
    writefln("SHA1: %(%02x%)", hasher.finish());  
    //verify that our nice pipeline is OK ;)
    writefln("Verify SHA1: %(%02x%)", sha1Of("Hello, world!\n"));
}