Upscale images nicely

Main.as

package
{
	import flash.display.*;
	import flash.events.*;
	import flash.utils.*;
	import flash.net.*;
	
	[SWF(width = "640", height = "480", backgroundColor="#000000")]
	public class Main extends Sprite
	{
		public var image:Bitmap;
		
		public function Main ()
		{
			image = new Bitmap;
			addChild(image);
			
			stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
		}
		
		public function onKeyDown (e:KeyboardEvent):void
		{
			if (e.keyCode == 27 || e.keyCode == 82) {
				// Escape or R = reset
				image.bitmapData = null;
			} else if (e.keyCode == 79) {
				// O = open
				load();
			} else if (e.keyCode == 83) {
				// S = save
				new FileReference().save(PNGEncoder.encode(image.bitmapData));
			} else if (e.keyCode >= 49 && e.keyCode <= 57) {
				// Numbers 1-9
				var scaleAmount:int = e.keyCode - 48;
				scale(scaleAmount);
			}
		}
		
		public function load (): void
		{
			var file: FileReference = new FileReference();
			file.addEventListener(Event.SELECT, fileSelect);
			file.browse([new FileFilter("Images", "*.jpg;*.jpeg;*.gif;*.png")]);
			
			function fileSelect (event:Event):void {
				file.addEventListener(Event.COMPLETE, loadComplete);
				file.load();
			}

			function loadComplete (event:Event):void {
				load2(file.data);
			}
		}
		
		public function load2 (data:ByteArray):void
		{
			var loader: Loader = new Loader();
			loader.loadBytes(data);
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, complete);
			
			function complete (e: Event):void
			{
				image.bitmapData = Bitmap(loader.content).bitmapData;
			}
		}
		
		public function scale (scale:int):void
		{
			var bitmap:BitmapData = image.bitmapData;
			
			while ((scale % 2) == 0) {
				bitmap = ScaleX.scale2x(bitmap);
				scale /= 2;
			}
			
			while ((scale % 3) == 0) {
				bitmap = ScaleX.scale3x(bitmap);
				scale /= 3;
			}
			
			if (scale != 1) {
				throw new Error("Can only scale by multiples of 2 and 3 :(");
			}
			
			image.bitmapData = bitmap;
		}
	}
}

PNGEncoder.as

/*
  Copyright (c) 2008, Adobe Systems Incorporated
  All rights reserved.

  Redistribution and use in source and binary forms, with or without 
  modification, are permitted provided that the following conditions are
  met:

  * Redistributions of source code must retain the above copyright notice, 
    this list of conditions and the following disclaimer.
  
  * Redistributions in binary form must reproduce the above copyright
    notice, this list of conditions and the following disclaimer in the 
    documentation and/or other materials provided with the distribution.
  
  * Neither the name of Adobe Systems Incorporated nor the names of its 
    contributors may be used to endorse or promote products derived from 
    this software without specific prior written permission.

  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR 
  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/
package
{
	import flash.geom.*;
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.utils.ByteArray;

	/**
	 * Class that converts BitmapData into a valid PNG
	 */	
	public class PNGEncoder
	{
		/**
		 * Created a PNG image from the specified BitmapData
		 *
		 * @param image The BitmapData that will be converted into the PNG format.
		 * @return a ByteArray representing the PNG encoded image data.
		 * @langversion ActionScript 3.0
		 * @playerversion Flash 9.0
		 * @tiptext
		 */			
	    public static function encode(img:BitmapData):ByteArray {
	        // Create output byte array
	        var png:ByteArray = new ByteArray();
	        // Write PNG signature
	        png.writeUnsignedInt(0x89504e47);
	        png.writeUnsignedInt(0x0D0A1A0A);
	        // Build IHDR chunk
	        var IHDR:ByteArray = new ByteArray();
	        IHDR.writeInt(img.width);
	        IHDR.writeInt(img.height);
	        IHDR.writeUnsignedInt(0x08060000); // 32bit RGBA
	        IHDR.writeByte(0);
	        writeChunk(png,0x49484452,IHDR);
	        // Build IDAT chunk
	        var IDAT:ByteArray= new ByteArray();
	        for(var i:int=0;i < img.height;i++) {
	            // no filter
	            IDAT.writeByte(0);
	            var p:uint;
	            var j:int;
	            if ( !img.transparent ) {
	                for(j=0;j < img.width;j++) {
	                    p = img.getPixel(j,i);
	                    IDAT.writeUnsignedInt(
	                        uint(((p&0xFFFFFF) << 8)|0xFF));
	                }
	            } else {
	                for(j=0;j < img.width;j++) {
	                    p = img.getPixel32(j,i);
	                    IDAT.writeUnsignedInt(
	                        uint(((p&0xFFFFFF) << 8)|
	                        (p>>>24)));
	                }
	            }
	        }
	        IDAT.compress();
	        writeChunk(png,0x49444154,IDAT);
	        // Build IEND chunk
	        writeChunk(png,0x49454E44,null);
	        // return PNG
	        return png;
	    }
	
	    private static var crcTable:Array;
	    private static var crcTableComputed:Boolean = false;
	
	    private static function writeChunk(png:ByteArray, 
	            type:uint, data:ByteArray):void {
	        if (!crcTableComputed) {
	            crcTableComputed = true;
	            crcTable = [];
	            var c:uint;
	            for (var n:uint = 0; n < 256; n++) {
	                c = n;
	                for (var k:uint = 0; k < 8; k++) {
	                    if (c & 1) {
	                        c = uint(uint(0xedb88320) ^ 
	                            uint(c >>> 1));
	                    } else {
	                        c = uint(c >>> 1);
	                    }
	                }
	                crcTable[n] = c;
	            }
	        }
	        var len:uint = 0;
	        if (data != null) {
	            len = data.length;
	        }
	        png.writeUnsignedInt(len);
	        var p:uint = png.position;
	        png.writeUnsignedInt(type);
	        if ( data != null ) {
	            png.writeBytes(data);
	        }
	        var e:uint = png.position;
	        png.position = p;
	        c = 0xffffffff;
	        for (var i:int = 0; i < (e-p); i++) {
	            c = uint(crcTable[
	                (c ^ png.readUnsignedByte()) & 
	                uint(0xff)] ^ uint(c >>> 8));
	        }
	        c = uint(c^uint(0xffffffff));
	        png.position = e;
	        png.writeUnsignedInt(c);
	    }
	}
}

ScaleX.as

package {

	/**
	 * @author nicoptere
	 */
	import flash.display.BitmapData;
	 
	public class ScaleX 
	{
		static public function scale1x (bd:BitmapData):BitmapData
		{
			return bd;
		}
		
		static public function scale4x (bd:BitmapData):BitmapData
		{
			return scale2x(scale2x(bd));
		}
		
		static public function scale2x( bd:BitmapData ):BitmapData
		{
			var dest:BitmapData = new BitmapData( bd.width*2, bd.height*2, true );
			
			var E:uint;
			var E0:uint;
			var E1:uint;
			var E2:uint;
			var E3:uint;
			
			var B:uint;
			var D:uint;
			var F:uint;
			var H:uint;
			
			var i:int;
			var j:int;
			var i2:int;
			var j2:int;
			
			var w:int = bd.width;
			var h:int = bd.height;
			bd.lock();
			dest.lock();
			for ( i = 0; i < w; i+=1 )
			{
				for ( j = 0; j < h; j+=1 )
				{
					
					E = bd.getPixel32( i, j );
					
					//on est sur un bord
					if( i==0 || j==0 || i == w-1 || j == h-1 )
					{
						
						E0 = E;
						E1 = E;
						E2 = E;
						E3 = E;
						
					}else{
					
						B = bd.getPixel32( i, j-1 );
						D = bd.getPixel32( i-1, j );
						F = bd.getPixel32( i+1, j );
						H = bd.getPixel32( i, j+1 );
						
						if (B != H && D != F ) 
						{
							
							E0 = ( D == B ) ? D : E;
							E1 = ( B == F ) ? F : E;
							E2 = ( D == H ) ? D : E;
							E3 = ( H == F ) ? F : E;
							
						}else{
							
							E0 = E;
							E1 = E;
							E2 = E;
							E3 = E;
							
						}
					}
					
					i2 = i*2;
					j2 = j*2;
					dest.setPixel32(   i2,   j2, E0 );
					dest.setPixel32( i2+1,   j2, E1 );
					dest.setPixel32(   i2, j2+1, E2 );
					dest.setPixel32( i2+1, j2+1, E3 );
					
				}
			}
			bd.lock();
			dest.unlock();
			return dest;
		}
		
		static public function scale3x( bd:BitmapData ):BitmapData
		{
			var dest:BitmapData = new BitmapData( bd.width*3, bd.height*3, true );
			
			var E:uint;
			
			var E0:uint;
			var E1:uint;
			var E2:uint;
			var E3:uint;
			var E4:uint;
			var E5:uint;
			var E6:uint;
			var E7:uint;
			var E8:uint;
			
			var A:uint;
			var B:uint;
			var C:uint;
			var D:uint;
			var F:uint;
			var G:uint;
			var H:uint;
			var I:uint;
			
			var i:int;
			var j:int;
			
			var i3:int;
			var j3:int;
			
			var w:int = bd.width;
			var h:int = bd.height;
			
			bd.lock();
			dest.lock();
			for ( i = 0; i < w; i+=1 )
			{
				for ( j = 0; j < h; j+=1 )
				{
		
					E = bd.getPixel32( i, j );
					
					//on est sur un bord
					if( i==0 || j==0 || i == w-1 || j == h-1 )
					{
						
						E0 = E;
						E1 = E;
						E2 = E;
						E3 = E;
						E4 = E;
						E5 = E;
						E6 = E;
						E7 = E;
						E8 = E;
						
					}else{

						A = bd.getPixel32( i-1, j-1 );
						B = bd.getPixel32(   i, j-1 );
						C = bd.getPixel32(   i, j+1 );
						D = bd.getPixel32( i-1, j );
						F = bd.getPixel32( i+1, j );
						G = bd.getPixel32( i-1, j+1 );
						H = bd.getPixel32(   i, j+1 );
						I = bd.getPixel32( i+1, j+1 );
						
						if ( B != H && D != F ) 
						{
							
							E0 = ( D == B ) ? D : E;
							E1 = ( ( D == B && E != C ) || ( B == F && E != A ) ) ? B : E;
							E2 = ( B == F )? F : E;
							E3 = ( ( D == B && E != G ) || ( D == H && E != A ) ) ? D : E;
							E4 = E;
							E5 = ( ( B == F && E != I ) || ( H == F && E != C ) ) ? F : E;
							E6 = ( D == H ) ? D : E;
							E7 = ( ( D == H && E != I ) || ( H == F && E != G ) ) ? H : E;
							E8 = ( H == F ) ? F : E;
							
						} else {
							
							E0 = E;
							E1 = E;
							E2 = E;
							E3 = E;
							E4 = E;
							E5 = E;
							E6 = E;
							E7 = E;
							E8 = E;
						
						}
					}
					i3 = i*3;
					j3 = j*3;
					
					dest.setPixel32(   i3, j3, E0 );
					dest.setPixel32( i3+1, j3, E1 );
					dest.setPixel32( i3+2, j3, E2 );
					
					dest.setPixel32(   i3, j3+1, E3 );
					dest.setPixel32( i3+1, j3+1, E4 );
					dest.setPixel32( i3+2, j3+1, E5 );
					
					dest.setPixel32(   i3, j3+2, E6 );
					dest.setPixel32( i3+1, j3+2, E7 );
					dest.setPixel32( i3+2, j3+2, E8 );
					
				}
			}
			bd.unlock();
			dest.unlock();
			return dest;
		}
	}
}