Fish-functions

first.fish

function first
  for file in $argv
    echo "$file"
    dd if="$file" count=25 status=none | head -n1
    echo ""
  end
end

groupby.fish

function groupby
  for o in (cut -d ',' -f 1 $argv[1] | uniq)
    echo -n "{\"$o\":["
    grep "$o," "$argv[1]" | cut -d ',' -f 2 | sed 's/^\(.*\)$/"\1"/' | tr '\n' ','| sed 's/,$//'
    echo "]}"
  end
end

man.fish

function man --description 'Format and display the on-line manual pages'
	
    set -l manpath
    if set -q MANPATH
        set manpath $MANPATH
    else
        set manpath ''
    end
    # Notice the shadowing local exported copy of the variable.
    set -lx MANPATH $manpath

    # Prepend fish's man directory if available.
    set -l fish_manpath (dirname $__fish_data_dir)/fish/man
    if test -d $fish_manpath
        set MANPATH $fish_manpath $MANPATH
    end

    set -lx LESS_TERMCAP_mb (printf "\e[1;33m")
    set -lx LESS_TERMCAP_md (printf "\e[1;31m")
    set -lx LESS_TERMCAP_me (printf "\e[0m")
    set -lx LESS_TERMCAP_se (printf "\e[0m")
    set -lx LESS_TERMCAP_so (printf "\e[1;44;33m")
    set -lx LESS_TERMCAP_ue (printf "\e[0m")
    set -lx LESS_TERMCAP_us (printf "\e[1;32m")

    command man $argv
end

now.fish

function now
	date "+%F_%T"
end