Grammar description for generating plausible-sounding anime titles. for use with polygen.

animetitles.grm

I ::= "title: Anime Titles\n"
    ^ "author: Jake Humphrey\n"
    ^ "language: english\n"
    ^ "status: Basic\n"
    ^ "topic: Anime\n"
    ^ "created: 22/01/2013\n"; 

S ::= +++++++++++++(\Object [and Object][^"!"])
      | \Exclamation ^ "!"[^"!"[^"!"]] \Name
      | '^\Object "Can't Possibly be this" \Adjective ^'
      | \Article \Person (is|was) [not] ["Going to be"] Article \Person
      | \Question is Object ^ "?";

Exclamation ::= dokidoki | haiyore | ganbare | faito | wasshoi | "shoubu da";

Question ::= who | how | where | what;

Name ::= Kana ^ Kana [^Kana] [^Kana]
     	 [^ "-" ^ (san | chan | kun | sama | nyan | dono)];

Vowel ::= a|e|i|o|u;

Kana ::= Vowel |
     	 (r|m|k|s|n|g|p)^Vowel |
	 t^(a|su|e|o) | chi |
	 h^(a|i|e|o) | fu |
	 y^(a|u|o) |
	 z^(a|u|e|o) | ji |
	 d^(a|e|o);

Article ::= a | the | "a Certain" | my | your | their | our | \Name ^ 's | a \Person^'s;

Object ::= [Article] \Description \Noun
       	   | Article \Noun
	   | Article \Description \Noun
	   | \Name
	   | \Description \Person \Name
	   | \Description (\Place | \Thing) \Person \Name
	   | [Article] \Noun Preposition [Article] \Noun
	   | [Article] \Noun ^"," [Article] \Noun;

Adjective ::= crazy | cute | lovely | dark | magic[^al] | [un^]scientific | lyrical | [un^]lucky | little | small | big | large | old | pure | perverted | exciting | boring | [extra^]ordinary | (north | east | south | west)^ern;

Description ::= ++++++++Adjective | PresPart | black | death | 'C' | demon | fairy | excel | speed | sunshine | combat | fire | earth | wind | water | robot | destiny | fate | love | "GJ";

Noun ::= Person | Place | Thing;

Place ::= [high|middle|elementary] "School" | paradise | heaven | world | planet | shrine | castle | academia | riverbank;

Person ::= Profession | boy | girl | man | woman | angel | devil | brother | sister | maid | pervert | mermaid | butler | maiden | husband | wife | child | robot | nymphet | wizard | witch | prince[^ss] | cat | dog | titan | eoten | soldier | nurse;

Thing ::= note | blade | channel | star | story | index | saga | days | sketch | rock | harem | busters | legend | life | death | time | "Daily Life" | cloud | magic | music | ++++++club | end | beats | soul | attack | edge | crime | [rail^]gun | date | rhythm | panties | billiards | game | mahjong | code | "mobile suit" | chuunibyou | delusions | virus | heart | panic;

Verb ::= shoot | fight | bludgeon | graph | travel | sever | undress;

PresPart ::= Verb^ing | racing | moving;

Profession ::= Verb^er | racer;

Preposition ::= of | on | onto | in | into | with | without | under | over;