Remove .CR2 files w/o .jpg file near

cr2-remover.bat

@echo off
REM Move to "deleted" directory .CR2 files w/o .jpg file placed near in current directory
setlocal enabledelayedexpansion

set workDir=
set rawExtension=.CR2
set jpgExtension=.jpg
set filesToRemove=

echo Looking for "*!rawExtension!" w/o "*!jpgExtension!" in current directory

for %%r in (%workDir%*!rawExtension!) do (
  if not exist %workDir%%%~nr!jpgExtension! (
    set /A counter+=1
    set filesToRemove=!filesToRemove!;%%~nr
  )
)

if %counter% gtr 0 (
  echo Ready to remove !counter! files
  pause
  if not exist "deleted" mkdir deleted
  for %%f in (%filesToRemove%) do (
    move !workDir!%%f!rawExtension! deleted\!workDir!%%f!rawExtension!
    echo Remove: !workDir!%%f!rawExtension!
  )
)

remover-verbose.bat

@echo off

setlocal enabledelayedexpansion

set verbose=TRUE
set workDir=%1
set action=%2
set rawExtension=.CR2
set jpgExtension=.jpg
set counter=0
set filesToRemove=

if "%workDir%" == "" (
  echo Please set first argument as working dir path
  goto :EOF
)

if "%action%" neq "" (
  if "%action%" equ "remove" (
      set verbose=FALSE
  )
)

echo Looking for "*!rawExtension!" w/o "*!jpgExtension!" in !workDir!

for %%r in (%workDir%*!rawExtension!) do (
  if not exist %workDir%%%~nr!jpgExtension! (
    set /A counter+=1
    set filesToRemove=!filesToRemove!;%%~nr
  )
)

if %counter% gtr 0 (
    if %verbose% == TRUE (
      echo Find !counter! files to remove:
      for %%f in (%filesToRemove%) do (
        echo %%f!rawExtension!
      )
    )

    if %verbose% == FALSE (
      echo Ready to remove !counter! files
      pause
      for %%f in (%filesToRemove%) do (
        del !workDir!%%f!rawExtension!
        echo Remove: !workDir!%%f!rawExtension!
      )
    )
) else (
  echo No files found
)

remover-verbose
http://www.evernote.com/shard/s135/sh/47fbbecb-0ba1-4b10-abbe-b6b8deffd09f/faadc95a2a1b24e4a633b2282f65f90a