Indirect Expand Lambda

IndirectExpand.lambda

/*
Name:  Indirect Expand (IndirectExpand)
Description:  Converts a range address (and optional sheet name) to a reference to those cells and the cells surrounding them by a user specified distance.
Parameters:
   address - range address text
   [sheet_name] - name of sheet, if not active sheet
   [expand_distance] - number of cells in all directions to expand the selection (default: 0)
Source:  @ExcelRobot
*/
IndirectExpand =LAMBDA(address, [sheet_name], [expand_distance], LET(
   \\LambdaName, "IndirectExpand",
   \\CommandName, "Indirect Expand",
   \\Description, "Converts a range address (and optional sheet name) to a reference to those cells and the cells surrounding them by a user specified distance.",
   \\Parameters, {
      "address","range address text";
      "[sheet_name]","name of sheet, if not active sheet";
      "[expand_distance]","number of cells in all directions to expand the selection (default: 0)"
      },
   \\Source, "@ExcelRobot",
   _Prefix, IF(
      ISOMITTED(sheet_name),
      "",
      "'" & SUBSTITUTE(sheet_name, "''", "'") & "'!"
   ),
   _Address, _Prefix & address,
   _Result, IF(
      ISOMITTED(expand_distance),
      INDIRECT(_Address),
      OFFSET(
         INDIRECT(_Address),
         -expand_distance,
         -expand_distance,
         ROWS(INDIRECT(_Address)) + 2 * expand_distance,
         COLUMNS(INDIRECT(_Address)) + 2 * expand_distance
      )
   ),
   _Result
));