ExMachina Formatters

formatters.ex

defmodule ExMachina.Sequence.Formatters do
  @moduledoc false

  @latin_letters 26
  @codepoint_start 65
  @spec to_alpha_code(integer(), integer()) :: String.t()
  @doc """
  Converts an integer (like a sequence counter) to an n-letter uppercase code.

  Examples:
  iex> Formatters.to_alpha_code(5)
  "AAE"
  iex> Formatters.to_alpha_code(500)
  "ATF"
  iex> Formatters.to_alpha_code(5000000)
  "MLR"
  iex> Formatters.to_alpha_code(5, 2)
  "AE"
  """
  def to_alpha_code(counter, code_length \\ 3) do
    counter_to_alpha =
      (counter - 1)
      # Convert our integer to base-26 (number of letters in the latin alphabet)
      |> Integer.digits(@latin_letters)
      # Shift the resulting digits so they match the codepoints of the alphabet
      |> Enum.map(&(&1 + @codepoint_start))

    # Prefix with As to ensure we have at least `code_length` chars
    ['A']
    |> List.duplicate(code_length - 1)
    |> Kernel.++(counter_to_alpha)
    # If our chars are too many, just take the last `code_length` chars.
    |> Enum.take(-code_length)
    |> to_string()
  end
end