Getting Gradle to resolve path to agent dependencies

gradle_aop_agent.gradle

// BEGIN: Dynamic agent JAR config
configurations {
    runtimeAgent
}
// END: Dynamic agent JAR config

buildscript {
    ext {
        springBootVersion = '1.5.2.RELEASE'
    }
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
    }
}

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'org.springframework.boot'

jar {
    baseName = 'sample'
    version = '0.0.1-SNAPSHOT'
}

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    compile('org.springframework.boot:spring-boot-starter-aop')
    compile("org.springframework.boot:spring-boot-starter-web")

    testCompile('org.springframework.boot:spring-boot-starter-test')

    // BEGIN: Dynamic agent JAR config
    runtimeAgent("org.aspectj:aspectjweaver")
    runtimeAgent("org.springframework:spring-instrument")
    // END: Dynamic agent JAR config
}

// BEGIN: Dynamic agent JAR config
test.doFirst {
    configurations.runtimeAgent.each {
        File jarFile ->
            jvmArgs("-javaagent:${jarFile.absolutePath}")
    }
}

bootRun.doFirst {
    configurations.runtimeAgent.each {
        File jarFile ->
            jvmArgs("-javaagent:${jarFile.absolutePath}")
    }
}
// END: Dynamic agent JAR config