ilyabirman.ru instant view template

!not_exists: (//article)[2]
?path: /meanwhile/.+
?path: /world/.+
?path: /music/.+

title: //h1[has-class("e2-smart-title")]
title: //div[has-class("page-title")]/h1
body: //article/div[has-class("e2-note-text")]
body: //div[has-class("narrative")]
body: //div[has-class("main")]
author: //div[has-class("menu-photo")]/next-sibling::div[has-class("menu-item")]/div[has-class("menu-link")]
author_url: //a[has-class("menu-logo")]/@href
channel: "@ilyabirman_channel"

$timestamp: //span[has-class("e2-timestamp")]
@remove: $timestamp/text()
@append(@title): $timestamp
@datetime: $timestamp
published_date: $@

<figure>: //div[has-class("e2-text-picture")]
<figure>: //div[has-class("e2-text-video")]
<figcaption>: //div[has-class("e2-text-caption")]
<slideshow>: //div[has-class("fotorama")]

$calliope: //div[has-class("e2-text-calliope-formatted")]
@wrap(<figure>): $calliope/img
# @debug
<figcaption>: $calliope/small
@append_to("./preceding-sibling::figure[1]"): $@


cover: //div[has-class("e2-note-text")]/figure[not(preceding-sibling::*)]

@remove: //div[has-class("likely-container")]