The full program for streaming a new random number each second.

ARandomNumberASecond.elm

module ARandomNumberASecond exposing (main)

import Html exposing (..)
import Html.App
import Time exposing (Time, second)
import Random


type alias Flags = {randSeed : Int}


main : Program Flags
main =
  Html.App.programWithFlags
    { init = init
    , update = update
    , view = view
    , subscriptions = subscriptions
    }


-- MODEL


type alias Model =
  { currentSeed : Random.Seed
  , numbers : List Int
  }


init : Flags -> (Model, Cmd Msg)
init {randSeed} =
  ( { currentSeed = Random.initialSeed randSeed
    , numbers = [ ]
    }
  , Cmd.none
  )


-- UPDATE


type Msg = Tick Time


update : Msg -> Model -> (Model, Cmd Msg)
update _ {currentSeed, numbers} =
  let
    (number, nextSeed) = Random.step (Random.int 1 100) currentSeed
  in
    ( { currentSeed = nextSeed
      , numbers = numbers ++ [number]
      }
    , Cmd.none
    )


-- SUBSCRIPTIONS


subscriptions : Model -> Sub Msg
subscriptions _ =
  Time.every second Tick


-- VIEW


view : Model -> Html Msg
view {currentSeed, numbers} =
  case numbers of
    [ ] ->
      viewLoading
    _ ->
      viewNumbers numbers


viewLoading : Html Msg
viewLoading =
  text "Loading..."


viewNumbers : List Int -> Html Msg
viewNumbers numbers =
  div [ ] (List.map viewNumber numbers)


viewNumber : Int -> Html Msg
viewNumber n =
  p [ ] [text (toString n)]