Set Skype Mood Message to what's playing on Spotify

nowplaying.applescript

on getCurrentlyPlayingTrack()
	tell application "Spotify"
		set currentArtist to artist of current track as string
		set currentTrack to name of current track as string
		return currentArtist & " - " & currentTrack
	end tell
end getCurrentlyPlayingTrack

on isSpotifyPlaying()
	tell application "Spotify"
		set appStatus to player state as string
		return appStatus = "playing"
	end tell
end isSpotifyPlaying

on getSkypeMoodMessage()
	tell application "Skype"
		return send command "GET PROFILE MOOD_TEXT" script name "Status-Script"
	end tell
end getSkypeMoodMessage

-- Let's keep the status
set currentStatus to getSkypeMoodMessage()

try
	repeat while 1 ≠ 0
		set currentSong to getCurrentlyPlayingTrack()

		if isSpotifyPlaying() then
			tell application "Skype"
				send command "SET PROFILE MOOD_TEXT (music) #nowplaying: " & currentSong script name "Status-Script"
			end tell
		else
			tell application "Skype"
				send command "SET " & currentStatus script name "Status-Script"
			end tell
		end if
		delay 2
	end repeat
on error ctrlC
	log ctrlC
	-- Alright, something broke. Enough fun, back to the original Mood Text
	tell application "Skype"
		send command "SET " & currentStatus script name "Status-Script"
	end tell
end try