Having some fun with https://hackage.haskell.org/package/typerep-map, can sorta carry around instances like this, caveat being keys have to be concrete ofc.

Main.hs

{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE TypeApplications #-}

module Main where

import qualified Data.TypeRepMap as TM
import Data.Typeable

data Shower a = Sf (a -> String)

type InstDict = TM.TypeRepMap Shower

instDict :: InstDict
instDict =
  TM.insert (Sf (\(_ :: Int -> Double) -> "a function from Int to Double")) $
    TM.insert (Sf $ show @String) $
      TM.insert (Sf $ show @Int) mempty

showy :: forall a. Typeable a => a -> String
showy v = case TM.lookup @a instDict of
  Nothing -> "<missing instance>"
  Just (Sf f) -> f v

main :: IO ()
main = do
  putStrLn $ showy (1 :: Int)
  putStrLn $ showy (2 :: Double)
  putStrLn $ showy ("Ahhh" :: String)
  putStrLn $ showy (realToFrac @Int @Double)
  putStrLn $ showy (id @Int)
{-
output:
1
<missing instance>
"Ahhh"
a function from Int to Double
<missing instance>
 -}