Listing Exercism problems not yet ported to Haskell

problem-diff.hs

#!/usr/bin/env stack
{- stack
  script
  --resolver lts-16.31
  --package containers
  --package http-client
  --package http-client-tls
  --package zip-archive
 -}

module Main
  ( main
  )
where

import qualified Codec.Archive.Zip as Zip
import Control.Monad
import Data.List
import qualified Data.Set as S
import Network.HTTP.Client
import Network.HTTP.Client.TLS

problemSpecSrc :: String
problemSpecSrc = "https://github.com/exercism/problem-specifications/archive/main.zip"

haskellSpecSrc :: String
haskellSpecSrc = "https://github.com/exercism/haskell/archive/main.zip"

getPracticeSet :: Manager -> String -> FilePath -> IO (S.Set String)
getPracticeSet mgr url magic = do
  req <- parseRequest url
  resp <- httpLbs req mgr
  let raw = responseBody resp
      arc = Zip.toArchive raw
      fSet = S.fromList $ do
        x <- Zip.filesInArchive arc
        guard $ magic `isPrefixOf` x
        let y = takeWhile (/= '/') $ drop (length magic) x
        guard $ not (null y)
        pure y
  pure fSet

main :: IO ()
main = do
  mgr <- newManager tlsManagerSettings
  hsSet <- getPracticeSet mgr haskellSpecSrc "haskell-main/exercises/practice/"
  specSet <- getPracticeSet mgr problemSpecSrc "problem-specifications-main/exercises/"
  let missing = S.difference specSet hsSet
  mapM_ print missing