https://www.mixmods.com.br/2022/08/sa-destructive-rhino-mod/

Destructive Rhino Mod (Junior_Djjr).sc

// by Junior_Djjr - MixMods.com.br
// You need: https://forum.mixmods.com.br/f141-gta3script-cleo/t5206-como-criar-scripts-com-cleoplus
SCRIPT_START
{
    LVAR_INT scplayer hVeh hChar iType i
    LVAR_FLOAT fIntensity

    WAIT 1000

    GET_PLAYER_CHAR 0 (scplayer)

    SET_SCRIPT_EVENT_CAR_PROCESS ON OnCarProcess hVeh
    SET_SCRIPT_EVENT_CAR_WEAPON_DAMAGE ON OnCarWeaponDamage hVeh

    WHILE TRUE
        WAIT 0x7FFFFFFF
    ENDWHILE

    OnCarProcess:
    IF IS_CAR_MODEL hVeh RHINO
        // required to use car process event because the game forces proofs every frame for army rhinos
        SET_CAR_PROOFS hVeh 1 1 0 1 1
    ENDIF
    RETURN_SCRIPT_EVENT

    OnCarWeaponDamage:
    IF IS_CAR_MODEL hVeh RHINO
        SET_CAR_PROOFS hVeh 1 1 1 1 1 //default
        GET_CAR_WEAPON_DAMAGE_LAST_FRAME hVeh hChar iType fIntensity
        //explosion by someone
        IF iType = WEAPONTYPE_EXPLOSION
        AND hChar > 0
            IF DOES_CHAR_EXIST hChar
                // ignore damage if the char is in car and is not player (eg cars exploding)
                GET_PED_TYPE hChar i
                IF IS_CHAR_IN_ANY_CAR hChar
                OR i <= 1 //except if player
                    IF NOT IS_CHAR_IN_CAR hChar hVeh //ignore damage by itself
                        SET_CAR_PROOFS hVeh 1 1 0 1 1
                    ENDIF
                ENDIF
            ENDIF
            //PRINT_FORMATTED_NOW "%x %i %f" 1000 hChar iType fIntensity
        ENDIF
    ENDIF
    RETURN_SCRIPT_EVENT
}
SCRIPT_END