https://www.mixmods.com.br/2021/09/clipboard-teleport-teletransporte-com.html

Clipboard Teleport (Junior_Djjr).sc

// by Junior_Djjr - MixMods.com.br
// You need: https://forum.mixmods.com.br/f141-gta3script-cleo/t5206-como-criar-scripts-com-cleoplus
SCRIPT_START
{
    LVAR_INT scplayer p i bEnabled keyJoker keyCopy keyPaste keyGround
    LVAR_FLOAT x y z

    GET_PLAYER_CHAR 0 scplayer

    READ_INT_FROM_INI_FILE "CLEO\Clipboard Teleport.ini" "Settings" "EnabledByDefault" (bEnabled)
    IF NOT READ_INT_FROM_INI_FILE "CLEO\Clipboard Teleport.ini" "Settings" "KeyJoker" (keyJoker) //ctrl 162
    OR NOT READ_INT_FROM_INI_FILE "CLEO\Clipboard Teleport.ini" "Settings" "KeyCopy" (keyCopy) //c 67
    OR NOT READ_INT_FROM_INI_FILE "CLEO\Clipboard Teleport.ini" "Settings" "KeyPaste" (keyPaste) //v 86
    OR NOT READ_INT_FROM_INI_FILE "CLEO\Clipboard Teleport.ini" "Settings" "KeyGround" (keyGround) //shift 160
        PRINT_STRING_NOW "~r~Fail to read 'CLEO\Clipboard Teleport.ini'" 10000
        TERMINATE_THIS_CUSTOM_SCRIPT
    ENDIF

    WHILE TRUE
        WAIT 0

        IF TEST_CHEAT CLIPT
            IF bEnabled = TRUE
                bEnabled = FALSE
                PRINT_STRING_NOW "~r~Clipboard Teleport DISABLED" 1000
            ELSE
                bEnabled = TRUE
                PRINT_STRING_NOW "~y~Clipboard Teleport ENABLED" 1000
            ENDIF
        ENDIF

        IF bEnabled = TRUE

            IF IS_KEY_PRESSED keyJoker
            AND IS_KEY_PRESSED keyPaste
                GET_LABEL_POINTER Buffer p
                READ_CLIPBOARD_DATA_TO p 128
                SCAN_STRING $p "%f %f %f" i (x y z)
                IF NOT i = 3
                    SCAN_STRING $p "%f,%f,%f" i (x y z)
                    IF NOT i = 3
                        CONTINUE
                    ENDIF
                ENDIF
                PRINT_FORMATTED_NOW "~g~Paste %.5f %.5f %.5f" 100 x y z
                REQUEST_COLLISION x y
                LOAD_SCENE x y z
                LOAD_ALL_MODELS_NOW
                IF IS_KEY_PRESSED keyGround
                OR timera < 200
                    z = -100.0
                    timera = 0
                ENDIF
                SET_CHAR_COORDINATES scplayer x y z
            ENDIF

            IF IS_KEY_PRESSED keyJoker
            AND IS_KEY_PRESSED keyCopy
                GET_CHAR_COORDINATES scplayer x y z
                IF IS_KEY_PRESSED keyGround
                OR timerb < 200
                    GET_GROUND_Z_FOR_3D_COORD x y z (z)
                    timerb = 0
                ENDIF
                GET_LABEL_POINTER Buffer p
                STRING_FORMAT p "%f %f %f" x y z
                PRINT_FORMATTED_NOW "~y~Copy %.5f %.5f %.5f" 100 x y z
                WRITE_CLIPBOARD_DATA_FROM p 128
            ENDIF

        ENDIF

    ENDWHILE

}
SCRIPT_END

Buffer:
DUMP
00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 
00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 
ENDDUMP