build.gradle.kts

plugins {
    id("eclipse")
}

eclipse {
    classpath {
        file {
            withXml {
                val classpath = asNode()
                val compositeBuildModuleNames = mutableSetOf<String>()
                configurations["runtimeClasspath"].resolvedConfiguration.resolvedArtifacts.forEach { artifact ->
                    val id = artifact.id.componentIdentifier
                    if (id is ProjectComponentIdentifier && !id.build.isCurrentBuild) {
                        val classpathEntry = classpath.appendNode("classpathentry")
                        classpathEntry.attributes().put("kind", "lib")
                        classpathEntry.attributes().put("path", artifact.file.absolutePath)
                        compositeBuildModuleNames.add(artifact.moduleVersion.id.name)
                    }
                }
                classpath.children().listIterator().apply {
                    while (hasNext()) {
                        val entry = next() as Node
                        val kind = entry.attribute("kind") as? String
                        val path = entry.attribute("path") as? String
                        if (kind == "src" && path != null && compositeBuildModuleNames.any { path.endsWith(it) }) {
                            remove()
                        }
                    }
                }
            }
        }
    }
}

Force eclipse to import gradle source repositories