An applescript to refresh the metadata of a selection in the Apple Music application (with progress bar)

refresh-music-selection.scpt

tell application "Music"
	-- get the selection
	set theSongs to selection
end tell

-- setup the progress bar
set theSongCount to length of theSongs
set progress total steps to theSongCount
set progress completed steps to 0
set progress description to "Refreshing Songs..."
set progress additional description to "Preparing to process."

-- iterate over the songs
repeat with i from 1 to theSongCount
	set theSong to item i of theSongs
	-- Update the progress detail
	-- get the metadata about the song
	tell application "Music"
		set theArtist to artist of theSong
		set theName to name of theSong
	end tell
	-- update the progress bar with additional information
	set progress additional description to i & "/" & theSongCount & " - " & theArtist & " - " & theName
	-- reload the song metadata from disk
	tell application "Music"
		refresh theSong
	end tell
	-- update the progress bar status
	set progress completed steps to i
end repeat

-- Reset the progress information
set progress total steps to 0
set progress completed steps to 0
set progress description to ""
set progress additional description to ""