analyzing Monster Hunter World combos using graph database Neo4J

mhw-moves.cypher

// clean db
MATCH(n) DETACH DELETE n;

// flowcharts: https://www.reddit.com/r/MonsterHunter/search?q=flow%20chart&restrict_sr=1
// motion values: https://www.reddit.com/r/MonsterHunter/comments/7v0pp3/mhworld_motion_values_compiled/
// motion frames: ???

// Long Sword
CREATE
(LongSwordDrawSlash:Move { weapon: "Long Sword", name: "Draw Slash", value: 25 });

// Hammer
CREATE
(hammerSheathed:Move { weapon: "Hammer", name: "Sheathed", value: 0 }),
(hammerSheathedMoving:Move { weapon: "Hammer", name: "Sheathed Moving", value: 0 }),
(hammerStationary:Move { weapon: "Hammer", name: "Stationary", value: 0 }),
(hammerMoving:Move { weapon: "Hammer", name: "Moving", value: 0 }),
(hammerUnsheathe:Move { weapon: "Hammer", name: "Unsheathe", value: 0 }),
(hammerUnsheatheAttack:Move { weapon: "Hammer", name: "Unsheathe Attack", value: 20 }),
(hammerSideSmash:Move { weapon: "Hammer", name: "Side Smash", value: 15 }),
(hammerReturnSwing:Move { weapon: "Hammer", name: "Return Swing", value: 16 }),
(hammerGroundSmashI:Move { weapon: "Hammer", name: "Ground Smash I", value: 37 }),
(hammerGroundSmashII:Move { weapon: "Hammer", name: "Ground Smash II", value: 22 }),
(hammerUpswing:Move { weapon: "Hammer", name: "Upswing", value: 86 })
WITH
hammerSheathed, hammerSheathedMoving, hammerStationary, hammerMoving, hammerUnsheathe, hammerUnsheatheAttack, hammerSideSmash, hammerReturnSwing, hammerGroundSmashI, hammerGroundSmashII, hammerUpswing
CREATE
(hammerSheathed)-[:FLOW {control: "stick"}]->(hammerSheathedMoving),
(hammerSheathedMoving)-[:FLOW {control: "△"}]->(hammerUnsheatheAttack),
(hammerStationary)-[:FLOW {control: "stick"}]->(hammerMoving),
(hammerSheathed)-[:FLOW {control: "△"}]->(hammerStationary),
(hammerMoving)-[:FLOW {control: "△"}]->(hammerSideSmash),
(hammerUnsheatheAttack)-[:FLOW {control: "△"}]->(hammerReturnSwing),
(hammerStationary)-[:FLOW {control: "△"}]->(hammerGroundSmashI),
(hammerGroundSmashI)-[:FLOW {control: "△"}]->(hammerGroundSmashII),
(hammerGroundSmashII)-[:FLOW {control: "△"}]->(hammerUpswing);

// hammer combos by total damage
MATCH p = (stationary:Move {name: "Stationary", weapon: "Hammer"})-[*]->(rest)
RETURN
    reduce(total = stationary.name, node IN tail(nodes(p)) | total + " → " + node.name) AS comboDescription,
    reduce(total = "", rel IN relationships(p) | total + " → " + rel.control) AS comboControls,
    reduce(total = 0, node IN nodes(p) | total + node.value) AS totalComboMotionValue
ORDER BY totalComboMotionValue DESC;