gdb-multiarch 15.1-1

PKGBUILD

# Maintainer: Aviel Warschawski <[email protected]>
# https://raw.githubusercontent.com/archlinuxcn/repo/e5e16b97748fa4b3ac4a070a1f4b3070bc651e9c/alarmcn/gdb-multiarch/PKGBUILD

pkgname=gdb-multiarch
_pkgname=${pkgname%-multiarch}
pkgver=15.1
pkgrel=1
pkgdesc="The GNU Debugger for all gdb supported architectures (i386/arm/mips...)"
arch=("i686" "x86_64" "aarch64")
url="http://www.gnu.org/software/${_pkgname}"
license=("GPL3")
makedepends=("texinfo" "python" "guile" "ncurses" "expat" "xz" "mpfr"
	"source-highlight" "boost" "readline")
depends=("ncurses" "libncursesw.so" "expat" "xz" "mpfr" "source-highlight" "gdb-common=${pkgver}"
	"readline" "libreadline.so" "guile" "python" "libelf")
source=(https://ftp.gnu.org/gnu/${_pkgname}/${_pkgname}-${pkgver}.tar.xz{,.sig})
sha256sums=('38254eacd4572134bca9c5a5aa4d4ca564cbbd30c369d881f733fb6b903354f2'
            'SKIP')

validpgpkeys=("F40ADB902B24264AA42E50BF92EDB04BFF325CF3") # Joel Brobecker <[email protected]>
options=("!emptydirs" "!lto")

prepare() {
	cd "${_pkgname}-${pkgver}/"
	sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure
}

build() {
	cd "${_pkgname}-${pkgver}/"

	mkdir -p build && cd build
	../configure \
		--enable-targets=all \
		--prefix=/build \
		--enable-languages=all \
		--enable-multilib \
		--enable-interwork \
		--with-system-readline \
		--disable-nls \
		--with-python=/usr/bin/python \
		--with-system-gdbinit="/etc/${_pkgname}/gdbinit"

	make
}

package() {
	cd "${_pkgname}-${pkgver}/build/"

	make DESTDIR="${pkgdir}" install

	# Following files conflict with "gdb" package
	install -Dm755 "${pkgdir}/build/bin/${_pkgname}" "${pkgdir}/usr/bin/${pkgname}"
	rm -r "${pkgdir}/build/"
}