Fila 1 (exemplo)

exemplo-fila-1.alg

Algoritmo "filas"
// Disciplina   : [Linguagem e Lógica de Programação]
// Professor   : Fernando Silva Maransatto
// Descrição   : Aqui você descreve o que o programa faz! (função)
// Autor(a)    : Nome do(a) aluno(a)
// Data atual  : 02/03/2021
Var
    fila: vetor[0..49] de caracter
    primeiro, ultimo: inteiro
    k: inteiro

    procedimento inserir()
    inicio
       se ultimo < 49 entao
          escreval("Digite um valor: ")
          leia(fila[ultimo])
          ultimo <- ultimo + 1
       senao
          escreval("Não existe mais espaço na fila")
       fimse
    fimprocedimento

    procedimento remover()
    var
       n: inteiro
    inicio

       se primeiro <> ultimo entao
          escreval("removido: ", fila[primeiro])
          para n de primeiro ate ultimo -1 faca
             fila[n] <- fila[n + 1]
          fimpara
          ultimo <- ultimo - 1
       senao
          escreval("Não existe elemento para remover")
       fimse

    fimprocedimento

    procedimento listar()
    var
       n: inteiro
    inicio
       escreval("---------------------")
       para n de primeiro ate ultimo -1 faca
          escreval(fila[n])
       fimpara

       se primeiro = ultimo entao
          escreval("... não tem nada...")
          escreval
       fimse
    fimprocedimento

    procedimento limpar()
    var
       n: inteiro
    inicio

       escreval("---------------------")
       para n de primeiro ate ultimo - 1 faca
          remover()
       fimpara

    fimprocedimento

    procedimento estaVazia()
    inicio
       se primeiro = ultimo entao
          escreval("sim... está vazia")
       senao
          escreval("não.... tem coisa aí")
       fimse
    fimprocedimento


    procedimento showMenu()
    var
       continuar, opcao: caractere
    inicio
       continuar := "s"

       enquanto continuar = "s" faca

          escreval("O que deseja fazer?")
          escreval("1 - inserir")
          escreval("2 - remover")
          escreval("3 - listar")
          escreval("4 - limpar")
          escreval("5 - está vazia?")
          escreval("6 - sair")
          leia(opcao)

          escolha opcao
          caso "1"
             inserir()
          caso "2"
             remover()
          caso "3"
             listar()
          caso "4"
             limpar()
          caso "5"
             estaVazia()
          caso "6"
             continuar := "n"
          fimescolha

       fimenquanto

    fimprocedimento

Inicio

   showMenu()


Fimalgoritmo