PKGBUILD for tree-sitter-symon

PKGBUILD

# Maintainer: Masaki Waga

pkgname=tree-sitter-symon-git
pkgver=.r0.g5c8d3dd
pkgrel=1
pkgdesc="SyMon grammar for tree-sitter"
arch=('i686' 'x86_64')
url="https://github.com/MasWag/tree-sitter-symon"
license=('MIT')
groups=('tree-sitter-grammars')
depends=('glibc')
makedepends=('git' 'nodejs' 'tree-sitter-cli')
provides=("tree-sitter-symon=$pkgver" 'libtree-sitter-symon.so')
conflicts=('tree-sitter-symon')
options=('staticlibs')
source=("git+https://github.com/MasWag/tree-sitter-symon.git")
sha256sums=('SKIP')


pkgver() {
  cd "tree-sitter-symon"

  _tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "tree-sitter-symon"

  tree-sitter generate
  CFLAGS="$CFLAGS -ffat-lto-objects" \
  make
}

check() {
  cd "tree-sitter-symon"

  tree-sitter test
}

package() {
  cd "tree-sitter-symon"

  make DESTDIR="$pkgdir" PREFIX="/usr" install
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/tree-sitter-symon"
  install -Dm644 "README.md" -t "$pkgdir/usr/share/doc/tree-sitter-symon"
}