How to augment the syntax to make DrRacket display information in a tooltip–LIVE! (without even saving the file!)

syntax-tooltip.rkt

#lang racket

;;; License: [MIT](http://opensource.org/licenses/MIT)
;;; Adapted from: https://github.com/samth/fancy-app

(begin-for-syntax
  (define (make-tooltip stx id msg)
    (define pos (syntax-position id))
    (define span (syntax-span id))
    (syntax-property
     stx
     'mouse-over-tooltips
     (and pos span (vector id (sub1 pos) (sub1 (+ pos span)) msg)))))

(define-syntax (FOO stx)
  (syntax-case stx ()
    [(_ id)
     (make-tooltip #'(display 'id)
                   #'id
                   (format "Identifier: ~a" (syntax-e #'id)))]))

(FOO yo)

Also look at the char-span example at the end of the docs on mouse-over-tooltips:

#lang racket
(define-syntax (char-span stx)
  (syntax-case stx ()
    [(_ a)
     (syntax-property
      #'a
      'mouse-over-tooltips
      (vector
       stx
       (sub1 (syntax-position stx))
       (sub1 (+ (syntax-position stx)
             (syntax-span stx)))
       (format "this expression\nspans ~a chars"
               (syntax-span stx))))]))
 
(char-span (+ 1 2))