Joycon re-pairing utility, See: https://www.reddit.com/r/yuzu/comments/11hssgt/

re_pair_joycons.bat

echo off
cls

echo ============================================================
echo Joycon re-pairing utility by Miigon
echo Useful for connecting Joycon to Bluetooth dongles that doesn't support 
echo proper reconnect. (eg. Realtek)
echo See: https://www.reddit.com/r/yuzu/comments/11hssgt/
echo ============================================================

C:

if exist "C:\Program Files (x86)\Bluetooth Command Line Tools\bin\" (
  cd "C:\Program Files (x86)\Bluetooth Command Line Tools\bin\"
  goto found
)

if exist "C:\Program Files\Bluetooth Command Line Tools\bin\" (
  cd "C:\Program Files\Bluetooth Command Line Tools\bin\"
  goto found
)

echo !!!! Please install BluetoothCLTools first and install it to the default C: folder. !!!
echo ==== After pressing any key, will redirect to the download page. ====
echo      or you can download it yourself at:
echo      https://bluetoothinstaller.com/bluetooth-command-line-tools/download.html
echo =====================================================================
pause
explorer "https://bluetoothinstaller.com/bluetooth-command-line-tools/download.html"
exit

:found

echo First, un-pair both joycons...
echo === Un-pairing Left Joycon ===
btpair.exe -u -n "Joy-Con (L)"
echo === Un-pairing Right Joycon ===
btpair.exe -u -n "Joy-Con (R)"
echo Next, pair both joycons once again.
echo === ATTENTION NEEDED ===
echo Before continuing, make sure BOTH of the joycons are in pairing mode.
echo (By holding the side pair button until the LED starts going up and down.)
echo Once they are, press any key on the keyboard to continue.
pause
echo ATTENTION NEEDED: Windows might prompt you to configure the newly connected joycons.
echo                   Please click the prompt and do that.
echo === Pairing Left Joycon ===
btpair.exe -p -n "Joy-Con (L)"
echo === Pairing Right Joycon ===
btpair.exe -p -n "Joy-Con (R)"
echo Ok. Should be done.
pause