F# CE quotation printer

gistfile1.fsx

// based on awesome https://www.fssnip.net/7OG/title/Quotation-Printer
module QuotationPrinter = 
    
    open System
    open Microsoft.FSharp.Quotations

    let private indent = 1

    let rec print depth (expr:Expr) = 
        match expr with
        | Patterns.Value (v, typ) -> sprintf "%A" v
        | Patterns.Var v ->  sprintf "%s:%s" v.Type.Name v.Name
        | Patterns.NewUnionCase (uci, args) -> 
            sprintf "%s(%s)" uci.Name (printArgs depth args)
        | Patterns.NewArray (_,args) -> 
            sprintf "[%s]" (printArgs depth args) 
        | Patterns.NewRecord (_,args) -> 
            sprintf "{%s}" (printArgs depth args)
        | Patterns.NewTuple args -> 
            sprintf "(%s)" (printArgs depth args)
        | Patterns.NewObject (ci, args) -> 
            sprintf "new %s(%s)" ci.Name (printArgs depth args)
        | Patterns.Call (Some (Patterns.ValueWithName(_,_,instance)), mi, args) -> 
            sprintf "%s.%s(%s)" instance mi.Name (printArgs (depth + 1) args)
        | Patterns.Call (None, mi, args) -> 
            sprintf "%s(%s)" mi.Name (printArgs (depth + 1) args)
        | Patterns.Lambda (var, body) -> 
            sprintf "(λ %s -> %s)" (print 0 (Expr.Var var)) (printArgs (depth + 1) [body])
        | Patterns.Let (var, bind, body) ->
            sprintf "let %s = %s in\r\n%*s%s" (print 0 (Expr.Var var)) (print 0 bind) ((depth - 1) * indent) "" (print depth body)
        | Patterns.PropertyGet (Some(var), pi, args) -> 
            sprintf "%s.%s" (print 0 var) pi.Name
        | Patterns.PropertySet (Some(var), pi, args, value) -> 
            sprintf "%s.%s <- %s" (print 0 var) pi.Name (print depth value)
        | Patterns.Sequential (x,y) -> 
            sprintf "%s; %s" (print depth x) (print depth y)
            
        | Patterns.Application (args, expr) ->
            sprintf "%s {%s}" (print depth expr) (printArgs (depth + 1) [args])
        | Patterns.Call (Some x, mi, args) -> 
            sprintf "%A.%s(%s)" x mi.Name (printArgs (depth + 1) args)
        | Patterns.PropertyGet (None, pi, args) ->
            sprintf "%s" pi.Name
        | Patterns.Coerce (expr, typ) ->
            sprintf "%s as %s" (print depth expr) typ.Name
        
        | a -> failwithf "Unknown patterns\n\n %A" a

    and printArgs depth args = 
        match args with
        | [a] -> sprintf "\r\n%*s%s\r\n%*s" (depth * indent) "" (print (depth + 1) a) (depth * indent) ""
        | a -> 
            sprintf "\r\n%*s%s" (depth * indent) "" (String.Join(sprintf ",\r\n%*s" (depth * indent) "",List.map (print (depth + 1)) a))

    let enableFSI() =
#if INTERACTIVE
        fsi.AddPrinter (fun (x:Expr) -> print 0 x)
#endif
        ()

QuotationPrinter.enableFSI()