Convert any D type to JSON automatically through trait/template magic

json.d

import std.stdio;
import std.conv;
import std.array;
import std.traits;

class Foo {
    Bar nested;

    this(Bar nested) {
        this.nested = nested;
    }
}

class Bar {
    string data;

    this(string data) {
        this.data = data;
    }
}

string json(T) (T obj) {
    static if (is(typeof(obj) == string)) {
        return "\"" ~ obj.replace("\\", "\\\\").replace("\"", "\\\"") ~ "\"";
    } else static if (isBasicType!(typeof(obj))) {
        return to!string(obj);
    } else {
        string res = "";

        foreach (mem; __traits(allMembers, typeof(obj))) {
            static if (!isCallable!(__traits(getMember, obj, mem)) && __traits(compiles, json(__traits(getMember, obj, mem)))) {
                auto val = __traits(getMember, obj, mem);
                res ~= "\"" ~ mem ~ "\":" ~ json(val) ~ ",";
            }
        }

        if (res.length > 0) res = res[0..$-1];

        return "{" ~ res ~ "}";
    }
}

void main() {
    Foo obj = new Foo(new Bar("Hello, world!"));
    
    writeln(json(obj));
}

give me the d