ClojureScript Leading Throttle utility

throttle.cljs

(ns pez.throttle)

(defonce !throttles (atom {}))

(defn dispatch! [{::keys [id timeout thunk]}]
  (let [maybe-schedule (fn [current-throttles]
                         (if (contains? current-throttles id)
                           current-throttles
                           (assoc current-throttles id
                                  {:timeout
                                   (delay
                                     (js/setTimeout
                                      (fn []
                                        (swap! !throttles dissoc id))
                                      timeout))})))
        [previous-throttles new-throttles] (swap-vals! !throttles maybe-schedule)]
    (when-not (contains? previous-throttles id)
      (-> new-throttles (get id) :timeout deref)
      (thunk))))

Yet another, yes. 😄

Use from some tight loop for whatever.

(throttle/dispatch! {::throttle/id ::boom
                     ::throttle/thunk #(js/console.log "BOOM!")
                     ::throttle/timeout 300})