archive output APK (AS 3.0 rc4)

.gitignore

/archive

[app-module]-build.gradle

def archiveTask = tasks.create(name: 'archive') {
    group 'archive'
    description "Assembles and archives all Release builds"
}

android.applicationVariants.all { variant ->
    def version
    if (variant.versionName != null && !variant.versionName.isEmpty())
        version = "${variant.versionName}-${variant.versionCode}"
    else
        version = "${variant.versionCode}"

    def archiveBuildTask = tasks.create(
            name: "archive${variant.name.capitalize()}Apk",
            type: Copy,
            dependsOn: variant.assemble,
    ) {
        group 'archive'
        description "Assembles and archives apk and its proguard mapping for the ${variant.name.capitalize()} build"

        variant.outputs.all { output ->
            from output.outputFile.path
            rename "${output.outputFile.name}", "${version}-${output.outputFile.name}"
        }
        if (variant.mappingFile != null) {
            from variant.mappingFile.path
            rename "${variant.mappingFile.name}", "${version}-${project.name}-${variant.flavorName}-${variant.buildType.name}-${variant.mappingFile.name}"
        }

        into "${rootDir}/archive/${project.name}/"
    }
    variant.assemble.finalizedBy archiveBuildTask
    archiveTask.dependsOn archiveBuildTask
}