Visualg TicTacToe

tictactoe.alg

Algoritmo "tictactoe"
// Disciplina   : CAP
// Professor    : Vânia
// Descrição   : jogo da velha
// Autor(a)    : Pedro Henrique Lara Campos
// Data atual  : 05/04/2016
Var
// Seção de Declarações das variáveis 
   mesa: vetor [0..2,0..2] de caracter
   turno: logico
   jogando,validarodada: logico
   xi,yi,zi: inteiro

Inicio
// Seção de Comandos, procedimento, funções, operadores, etc... 
   escreval("Vamos jogar tic-tac-toe?")
   
   para xi de 0 ate 2 faca
        para yi de 0 ate 2 faca
             mesa[xi,yi] <- " "
        fimpara
   fimpara
   
   turno <- falso
   jogando <- verdadeiro
   enquanto jogando faca
         escreval("   0 1 2")
         para xi de 0 ate 2 faca
              escreval(xi, ":", mesa[xi,0], "|", mesa[xi,1], "|", mesa[xi,2])
         fimpara
         escreva("Turno do jogador: ")
         se (turno) entao
            escreval("O")
         senao
              escreval("X")
         fimse
         validarodada <- verdadeiro
         enquanto validarodada faca
            escreva("Digite a linha: ")
            leia(xi)
            escreva("Digite a coluna: ")
            leia(yi)
            se (mesa[xi,yi] = " ") entao
               se (turno) entao
                  mesa[xi,yi] <- "O"
               senao
                    mesa[xi,yi] <- "X"
               fimse
               validarodada <- falso
            fimse
         fimenquanto
         se ((mesa[0,0] <> " ") e (mesa[0,0] = mesa[1,1]) e (mesa[0,0] = mesa[2,2])) entao
            escreval("Fim de jogo, vitória ", mesa[0,0])
            jogando <- falso
         senao
              se ((mesa[0,2] <> " ") e (mesa[0,2] = mesa[1,1]) e (mesa[0,2] = mesa[2,0])) entao
                 escreval("Fim de jogo, vitória ", mesa[0,2])
                 jogando <- falso
              senao
                   para xi de 0 ate 2 faca
                        se ((mesa[xi,0] <> " ") e (mesa[xi,0] = mesa[xi,1]) e (mesa[xi,0] = mesa[xi,2])) entao
                           escreval("Fim de jogo, vitória ", mesa[xi, 0])
                           jogando <- falso
                           interrompa
                        fimse
                   fimpara
                   para yi de 0 ate 2 faca
                        se ((mesa[0,yi] <> " ") e (mesa[0,yi] = mesa[1,yi]) e (mesa[0,yi] = mesa[2,yi])) entao
                           escreval("Fim de jogo, vitória ", mesa[0,yi])
                           jogando <- falso
                           interrompa
                        fimse
                   fimpara
              fimse
         fimse
         turno <- nao(turno)
   fimenquanto
Fimalgoritmo