PKGBUILD

# Contributor: Juan Diego Tascon
# Contributor: PkmX <[email protected]>

pkgname=artoolkit
pkgver=2.72.1
pkgrel=8
pkgdesc="Augmented Reality ToolKit"
arch=('i686' 'x86_64')
url="http://www.hitl.washington.edu/artoolkit/"
license=('GPL')
depends=('glut' 'gstreamer0.10' 'glu')
source=("http://downloads.sourceforge.net/project/artoolkit/artoolkit/${pkgver}/ARToolKit-${pkgver}.tgz")
md5sums=('4328b512711529309bad4bd1d791952c')

build() {
	cd ${srcdir}/ARToolKit
	echo -ne "5\ny\nn\n" | ./Configure

	for makefile in lib/SRC/*/Makefile; do
		sed '/^CFLAG/ s/=/= -fPIC/' -i "$makefile"
	done
	
        make -C lib/SRC

        rm include/AR/config.h.in
}

package()
{
	cd ${srcdir}/ARToolKit
	mkdir -p ${pkgdir}/usr/{lib,include}
	
        # Install header files
	cp -r include/AR ${pkgdir}/usr/include
	
	# Create shared libraries
	pushd lib
	for liba in *.a; do
		libso=$(basename $liba .a).so
		ld -shared -s -whole-archive $liba -o $libso
		cp $liba $libso ${pkgdir}/usr/lib/
	done
	popd
	
	# Install share
	mkdir -p ${pkgdir}/usr/share/artoolkit/
	cp -r bin/Data doc patterns examples ${pkgdir}/usr/share/artoolkit/
}