小さなEXEを作るテスト（2KB～）

build.bat

i686-w64-mingw32-gcc  -march=pentium -nostdlib -nodefaultlibs -fno-ident -fno-asynchronous-unwind-tables -nostartfiles tellpath.c -c -o tellpath.o
windres tellpath.rc -o res.o
ld tellpath.o res.o -olauncher.exe -T smallexe.lds -lkernel32 -luser32 --subsystem windows 
strip  -R .reloc launcher.exe
copy launcher.exe ..\launcher.exe /Y

note.md

note

2KBぐらいEXEファイルを作るテスト libcに頼らない、WindowsAPIを直接たたく小さいツール向け

point

gcc option

• -nostdlib -nodefaultlibs -nostartfiles: libc, mingw標準のあれこれをつけない
• -fno-ident: ファイル内に
• -fno-asynchronous-unwind-tables: eh_handlerとかを作らない？

strip

• -R .reloc: relocセクションを削除。小さいプログラムならいらないでしょう。

ld script

• .rdataと.textのマージ
  • Windowsではセクションがｎbyteの倍数でないとロードされない制約がある。
  • .rdataセクションを作られると、たった数バイトの文字列などのために結構なpaddingが挿入される
  • リンカスクリプトにより.textセクションに.rdataをマージする。
  • MSVCならリンカオプションで何とかなるが、gccだとリンカスクリプトを書く必要があった。

smallexe.lds

/* linker script for 2KB EXE / no libc */
/* ref: https://gist.github.com/pts/9ef2b1036d0b42508327559eeb2e0eb5 */

OUTPUT_FORMAT(pei-i386)
SEARCH_DIR("/usr/i686-pc-msys/lib"); SEARCH_DIR("/usr/lib"); SEARCH_DIR("/usr/lib/w32api");
SECTIONS {
  /* Make the virtual address and file offset synced if the alignment is
   * lower than the target page size.
   */
  . = SIZEOF_HEADERS;
  . = ALIGN(__section_alignment__);
  .text __image_base__ + (__section_alignment__ < 0x1000 ?
      . : __section_alignment__) : {
    *(.text) *(SORT(.text$*)) *(.text.*) *(.gnu.linkonce.t.*) *(.glue_7t)
    *(.glue_7)
     *(.rdata)
     *(SORT(.rdata$*))
  }
  .idata BLOCK(__section_alignment__) : {  /* This is pure magic. */
    SORT(*)(.idata$2)
    SORT(*)(.idata$3)
    /* These zeroes mark the end of the import list.  */
    LONG (0); LONG (0); LONG (0); LONG (0); LONG (0);
    SORT(*)(.idata$4)
    __IAT_start__ = .;
    SORT(*)(.idata$5)
    __IAT_end__ = .;
    SORT(*)(.idata$6)
    SORT(*)(.idata$7)
  }
}